Excel faylında hər gün daxil olan e-poçtların ümumi sayını necə avtomatik qeyd etmək olar

Bu məqalə sizə Outlook-a hər gün aldığınız neçə e-poçtu avtomatik saymağı və nömrəni Excel faylına yazmağı öyrədəcək.

Bir çox istifadəçidən hər gün alınan e-poçtların ümumi sayını hesablamaq tələb olunur. Bundan əlavə, gələcəkdə daha rahat yoxlama üçün, bir çoxları ümumi sayını Excel faylına yazmağa vərdiş edirlər. Bu halda, əlbəttə ki, hər gün əl ilə saymağı və qeyd etməyi seçə bilərsiniz. Bununla belə, bir az əziyyətlidir. Və bəzən bunu etməyi unuda bilərsiniz. Buna görə də, Outlook-u avtomatik olaraq bunu etməyə imkan verən lazımlı bir üsul arzulamalısınız. Bu tələbə cavab olaraq, biz sizə onu həyata keçirmək üçün VBA-dan necə istifadə edəcəyinizi aşağıda izah edəcəyik.

Excel faylında hər gün daxil olan e-poçtların ümumi sayını avtomatik qeyd edin

1. Ən başlanğıcda Outlook proqramınızı işə salın.
2. Sonra əsas Outlook pəncərəsində "Alt + F11" düymələri qısa yollarını basın.
3. Sonra açılan VBA redaktoru pəncərəsində “ThisOutlookSession” layihəsini açın.
4. Sonradan, aşağıdakı VBA kodlarını bu layihəyə köçürün və yapışdırın.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Sonra bu kodu imzalayın və imzalanmış makrolara icazə vermək üçün Outlook makro parametrlərinizi dəyişdirin.
6. Bundan sonra, gündəlik olaraq təkrarlanan bir tapşırıq yaratmalısınız.

• Əvvəlcə Tapşırıqlar panelində "Yeni tapşırıq" düyməsini basın.
• Açılan Yeni Tapşırıq pəncərəsində "Təkrarlanma" düyməsini basın.
• Sonra növbəti dialoq qutusunda “Gündəlik”, “Hər 1 gün(lər)” və “Bitmə tarixi yoxdur” seçin və nəhayət, “OK” düyməsini basın.
• Daha sonra ehtiyaclarınıza uyğun olaraq tapşırıq mövzusunu və xatırladıcısını dəyişdirin.
• Sonda "Saxla və Bağla" düyməsini basın.

7. Bundan sonra, bu tapşırığın xatırladıcısı hər dəfə xəbərdarlıq edəndə, Outlook avtomatik olaraq dünən alınan e-poçtları sayacaq və sonra aşağıdakı ekran görüntüsü kimi nömrəni Excel faylına yazacaq:

Daimi PST məlumat itkisindən qaçın

Heç kim daimi PST məlumat itkisini qəbul etməyə hazır deyil. Bununla belə, Outlook PST faylı korrupsiyaya meyllidir. Buna görə də, ardıcıl və müasir PST məlumatlarının ehtiyat nüsxəsini çıxarmaq və güclü bir məlumat saxlamaq kimi kifayət qədər ehtiyat tədbirləri görməlisiniz. PST bərpası yaxınlıqdakı alət kimi DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc sql təmiri və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com