Outlook-da cavab vermədiyiniz vacib e-poçtları avtomatik olaraq necə vurğulamaq olar

Vacib e-məktublara cavab verməyi yadda saxlamaq üçün Outlook-dan cavab vermədiyiniz vacib e-poçtları vurğulamaq üçün xüsusi manifest rəngdə göstərməsini istəyə bilərsiniz. İndi bu məqalə sizə onu necə əldə edəcəyinizi öyrədəcək.

Heç bir vacib e-poçtu qaçırmısınız və onlara vaxtında cavab verməmisiniz? Əgər belə problemlərlə üzləşmisinizsə, bəlkə Outlook-un cavab vermədiyiniz vacib e-poçtları vurğulaya biləcəyinə ümid edəcəksiniz. İndi, aşağıdakılarda, VBA ilə nail olmaq üçün sizə rəhbərlik edəcəyik. VBA ilə tanış olmamağınız şərti ilə, lütfən, mənim əvvəlki məqaləmə müraciət edin – “Outlook-da VBA kodunu necə işlətmək olar” bu arada.

Cavab vermədiyiniz Vacib E-poçtları avtomatik olaraq vurğulayın

1. Ən başlanğıcda Outlook-da “Alt + F11” vasitəsilə VBA redaktoruna daxil olun.
2. Sonra, yeni pəncərədə aşağıdakı kodu “ThisOutlookSession” layihəsinə köçürün.

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Bundan sonra, kursoru "Application_Startup" makrosuna aparın və "F5" düyməsini basın.
4. Daha sonra bu pəncərəni bağlayın.
5. Daha sonra Gələnlər qutusunda elementlər üçün şərti formatlaşdırma qaydası yaratmaq üçün aşağıdakı addımları yerinə yetirin.

• Əvvəlcə "Gələnlər qutusu" qovluğuna keçin.
• Sonra "Görünüş" sekmesine keçin və "Parametrlərə Bax" düyməsini basın.
• Yeni informasiya qutusunda "Şərti Formatlaşdırma" düyməsini basın.
• Növbəti "Şərti Formatlaşdırma" informasiya qutusunda "Əlavə et" düyməsini basın və yeni qayda üçün "Cavab verilməyən Vacib E-poçtlar" kimi bir ad daxil edin.
• Daha sonra “Şrift…” düyməsini sıxın və açılan “Şrift” informasiya qutusunda şrift üslubunu və rəngini təyin edin.
• Şrifti təyin etdikdən sonra "Şərti Formatlaşdırma" informasiya qutusunda "Şərt..." düyməsini basın.
• Daha sonra, "Filtr" ekranında, "Qabaqcıl" sekmesinde iki filtr əlavə edin.

1. “Əhəmiyyət” > “bərabərdir” > “Yüksək”
2. “Cavab verildi” > “(dəqiq)” > “Xeyr”

• Nəhayət, bu formatlaşdırma qaydasını saxlamaq üçün bir sıra "OK" düyməsini basın.

6. Gələnlər qutusuna qayıtdıqdan sonra cavab vermədiyiniz bütün vacib e-məktublar xüsusi şrift və rəngdə vurğulanıb.

Outlook Məlumat Qorumasında Sıxlıq etməyin

Saysız-hesabsız istifadəçilər hələ də məlumatların korlanmasının heç vaxt ağlına gəlməyəcəyi fikrini saxlayırlar. Əslində, bu cür fikirlər tamamilə səhv və risklidir. Əksər hallarda kiçik bir səhv asanlıqla məlumatların itirilməsinə səbəb ola bilər. Məsələn, naməlum e-poçtlarda təsadüfən zərərli bir linkə klikləsəniz, Outlook faylınız virusa yoluxmuş və hətta zədələnmiş ola bilər. Buna görə də, məlumatların qorunmasında hər zaman diqqətli olmalısınız, məsələn, müntəzəm PST ehtiyat nüsxəsini saxlamağa davam etməli və güclü bir düzəliş vasitəsi hazırlamalısınız, məsələn... DataNumen Outlook Repair, ola bilər Outlook-u düzəldin məsələlər bir anda.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc mdf bərpa edin və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com