Outlook VBA ilə daxil olan e-poçtların məlumatlarını Excel faylına necə ixrac etmək olar

Bir çox istifadəçi ümid edir ki, Outlook avtomatik olaraq daxil olan e-poçtların əsas məlumatlarını Excel faylına ixrac edə bilər. Bu məqalə bu tələbi nəzərdən keçirəcək və Outlook VBA vasitəsilə sürətli bir üsul təqdim edəcəkdir.

Bəzən, poçt statistikası kimi bəzi səbəblərə görə tez-tez e-poçtları Excel faylına ixrac etməli ola bilərsiniz. Ümumiyyətlə, mövcud qəbul e-poçtları üçün siz sadəcə olaraq onları Excel-ə ixrac etmək üçün “İdxal və İxrac” funksiyasından istifadə edə bilərsiniz. Bununla belə, ola bilsin ki, Outlook-un daxil olan e-poçtları poçt qutunuza gələn kimi avtomatik olaraq Excel-ə ixrac edə bilməsini arzulayırsınız. Şübhəsiz ki, Outlook-da belə bir yerli xüsusiyyət yoxdur. Buna görə də, üçüncü tərəf əlavəsi və ya Outlook VBA kimi digər yanaşmalardan istifadə etməlisiniz. Burada onu Outlook VBA ilə necə avtomatlaşdırmağı öyrədəcəyik. Addımları və kodları əldə etmək üçün oxuyun.

Gələn e-poçtların məlumatlarını Excel faylına avtomatik ixrac edin

1. İlk növbədə, bir Excel faylı yaratmalısınız.

• Yeni Excel faylı açın.
• Sonra "Xeyr" yazmalısınız. A1 xanasında, B1 xanasında “Göndərən adı”, C1 xanasında “Göndərən E-poçt ünvanı” və D1 xanasında “E-poçt mövzusu” və E1 xanasında “Qəbul edilən vaxt” aşağıdakı şəkildəki kimi.
• Nəhayət, onu istədiyiniz adda və istədiyiniz qovluqda saxlayın.

2. Bundan sonra Outlook-u işə salmalısınız.
3. Sonra sizi VBA redaktoruna gətirəcək "Alt + F11" düymələrini basın.
4. Açılan pəncərədə, sol tərəfdəki "ThisOutlookSession" düyməsini iki dəfə vurmalısınız.
5. Sonradan, “ThisOutlookSession” layihə pəncərəsində aşağıdakı VBA kodlarını kopyalayıb ona yapışdırmalısınız.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Daha sonra bu kodu imzalamalısınız.
7. Daha sonra, restart Yeni VBA layihəsini aktivləşdirmək üçün Outlook.
8. Nəhayət, bundan sonra bütün gələn e-poçtlar Gələnlər Qutusu qovluğuna düşən kimi əvvəlcədən təyin edilmiş Excel faylına avtomatik ixrac ediləcək. Excel faylı aşağıdakı şəkildəki kimi görünəcək:

Ağrılı PST Məlumat Korrupsiyasının qarşısını alın

Outlook müxtəlif xüsusiyyətlərinə görə çox rəğbət qazandı. Bununla belə, bu, o demək deyil ki, qüsursuzdur. Hələ də istənilən vaxt güzəştə gedə bilər. Məsələn, Outlook-unuzu tez-tez düzgün şəkildə bağlasanız, PST məlumatlarınızın təhlükə altına düşmə ehtimalı yüksəkdir. Bu vəziyyətdə, istəsəniz təmir PST kimi təcrübəli bir vasitəyə müraciət etməlisiniz DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc mdf bərpa edin və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com