Fərqli Səhifələrdə Fərqli Kateqoriyalarla Outlook Tapşırıqlarının Siyahılarını Çap Etməyin 2 Yolu

Outlook tapşırıqlarınıza müxtəlif rəng kateqoriyaları təyin etmisinizsə və indi müxtəlif səhifələrdə müxtəlif kateqoriyalı tapşırıqların siyahısını çap etmək istəyirsinizsə, bu məqaləyə müraciət edə bilərsiniz. Burada onu əldə etməyin 2 üsulunu sizinlə paylaşacağıq.

Tapşırıqlarınızı təsnif etmək və yaxşı idarə etmək üçün, ola bilsin, siz tapşırıqlarınıza rəng kateqoriyalarını tətbiq etmisiniz. İndi, müxtəlif səhifələrdə müxtəlif kateqoriyalara malik tapşırıqlarınızın siyahısını çap etmək istəyirsinizsə, lütfən oxuyun. Aşağıda onu əldə etmək üçün sizə 2 vasitə təqdim edəcəyik.

Metod 1: Tapşırıq siyahılarını bir-bir əl ilə çap edin

1. Əvvəlcə Outlook-da "Tapşırıqlar" bölməsinə daxil olun.
2. Sonra Tapşırıq qovluğunu açın.
3. Sonra, "Axtarış" lentini aktivləşdirmək üçün "Ctrl + E" düyməsini basın.
4. Bundan sonra, "Axtarış" sekmesinde, "Kateqoriyalara ayır" düyməsini basın.
5. Açılan siyahıdan rəng kateqoriyasını seçin.
6. Sonra siyahıda yalnız seçilmiş kateqoriyaya malik tapşırıqlar qalacaq.
7. İndi bu tapşırıq siyahısını çap etmək üçün “Fayl” > “Çap et” bölməsinə keçin.
8. Sonradan, eyni şəkildə, digər rəng kateqoriyaları ilə tapşırıqların siyahısını əl ilə bir-bir çap edin.

Metod 2: Tapşırıq siyahılarını VBA ilə toplu çap edin

1. Başlanğıcda VBA redaktorunu işə salın.Outlook-da VBA kodunu necə işlətmək olar".
2. Daha sonra, "MS Excel Obyekt Kitabxanası"na istinad əlavə edin.VBA-da Obyekt Kitabxanasına İstinad necə əlavə olunur".
3. Sonra, aşağıdakı VBA kodunu modula köçürün.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Daha sonra bu makronu dərhal işə salmaq üçün “F5” düyməsini sıxın.
5. Makro tamamlandıqda, aşağıdakı ekran görüntüsündə göstərildiyi kimi müxtəlif kateqoriyalı tapşırıqların siyahıları müxtəlif səhifələrdə çap olunacaq.

Təhlükəli PST faylından qiymətli məlumatları geri alın

Əgər əlçatmaz PST faylına məruz qalırsınızsa, şübhəsiz ki, növbəti addımınız olacaq PST təmiri. Bu halda, ilk növbədə, gələnlər qutusunu təmir alətini sınaya bilərsiniz. Əgər uğursuz olarsa, başqa bir xarici aləti sınamağa davam edə bilərsiniz, məsələn DataNumen Outlook Repair. Tez bir zamanda PST məlumatlarını bərpa edə bilir.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc mdf bərpa edin və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com