Outlook-da Göndərən tərəfindən e-poçtları tez saymaq üçün 2 üsul

E-poçtları göndərənə görə saymaq istəyirsinizsə, bu məqaləyə müraciət edə bilərsiniz. Burada sizə 2 sürətli yanaşma təqdim edəcəyik.

Ən aktiv göndərəni müəyyən etmək üçün göndərənə görə e-poçtları saymaq istəyə bilərsiniz. Outlook bunun üçün birbaşa funksiya təmin etməsə də, yenə də aşağıdakı 1-ci Metod kimi bəzi alternativ həllər axtara bilərsiniz. Əgər 1-ci Metodun çox yorucu olduğunu düşünürsünüzsə, 2-ci Metodu seçə bilərsiniz. Göndərənə görə e-poçtları tez bir zamanda saymaq və sayını Excel-ə ixrac etmək üçün VBA-dan istifadə etməsi səbəbindən daha təsirli olur. İndi iki yolu ətraflı oxuyun. Burada nümunə olaraq Gələnlər qutusundakı e-poçtları götürəcəyik.

Metod 1: Elementləri “Kimdən” sahəsinə görə qruplaşdırdıqdan sonra sayları əldə edin

1. Başlamaq üçün Outlook proqramını işə salın.
2. Sonra gələnlər qutusu qovluğunu açın.
3. Sonra, "Görünüş" sekmesine keçin.
4. Sonra, "Aranjman" qrupunda "Kimdən" seçin.
5. Eyni anda, bütün gələnlər qutusu müxtəlif göndərənlərə görə müxtəlif qruplara ayrıldı.
6. İndi müəyyən bir göndəricidən gələn maddələri saymaq üçün müvafiq qrupdakı bütün elementləri seçib “Enter” düyməsini sıxa bilərsiniz. Açılan xəbərdarlıqda siz sayı görə bilərsiniz.

Bu, kifayət qədər asandır, lakin maddələrin sayına təkcə e-poçt sayıları deyil, görüş dəvətləri, tapşırıq sorğuları və qəbzlər kimi digər növ elementlər də daxildir. Beləliklə, yalnız e-poçtları saymaq istəyirsinizsə, bunun əvəzinə aşağıdakı üsuldan istifadə edə bilərsiniz.

Metod 2: Outlook VBA ilə Göndərən tərəfindən e-poçtları sayın

1. Başlamaq üçün Outlook-da "Alt + F11" düymələrini basın.
2. Daha sonra, "MS Excel Obyekt Kitabxanası"nı ""ə uyğun olaraq aktivləşdirinVBA-da Obyekt Kitabxanasına İstinad necə əlavə olunur".
3. Sonra, aşağıdakı kodu istifadə olunmamış modula köçürün.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Bundan sonra "F5" düyməsini basın.
4. Makro bitdikdə yeni Excel faylı görünəcək.
5. Gördüyünüz kimi, o, müxtəlif göndərənlərdən gələn məktubların sayını ehtiva edir.

Əsəbiləşdirən Outlook Problemlərini aradan qaldırın

Bəlkə də Outlook-da bir çox problemlə üzləşmisiniz. Onları effektiv şəkildə həll etmək üçün çox yönlü və güclü bir yol arzulaya bilərsiniz. Ancaq əslində belə bir üsul yoxdur. Edə biləcəyiniz şey Outlook-da öz əməliyyatlarınızdan ehtiyat etmək və müntəzəm ehtiyat nüsxələrini çıxarmaqdır. Əlbəttə ki, mümkünsə, təcrübəli düzəliş alətini əlinizdə saxlamağınızı məsləhət görürük DataNumen Outlook Repair. Müxtəlif PST problemlərini həll edə və təmir edə bilər pozulmuş PST meh kimi fayl.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc bərpa edin Sql Server və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com