将 Word 文档快速转换为宏的 3 种方法 PDF 档

词解法 2025 年 9 月 28 日

在本文中，我们将重点为您提供3个宏，您可以使用它们将Word文档快速转换为 pdf 文件。

在 Word 2003 中，菜单栏上有一个图标。只需单击一下，用户就可以立即触发“另存为”窗口并将文档保存在 pdf 格式。

但是，正如您所注意到的，Word 2010 中的布局发生了很大变化。用户必须单击“文件”选项卡，然后单击“另存为”命令才能触发“另存为”窗口。此外，您必须在点击“保存”按钮之前手动选择保存类型。

即使点击这么多次，速度仍然不够快。因此，在本文中，我们将展示一种更快捷的宏观操作方法。

宏一：快速触发“另存为”窗口

首先，点击“开发工具”选项卡，然后点击“Visual Basic”命令打开VBA编辑器。当然，这两次点击操作必须在“开发工具”选项卡显示后才能进行。另一种方法是按“Alt+F11”组合键。
其次，单击“正常”项目。
第三，单击“插入”，然后在列表菜单上选择“模块”。
现在双击模块以显示编辑区域。
接下来，粘贴以下代码：

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

然后点击“运行”。

现在出现了“另存为”窗口。保存类型已设置为 PDF。只需点击“保存”按钮即可。此宏允许您在必要时更改文件名。

宏 2：直接将 Word 文件另存为 PDF

如果有人想直接将文件保存到 pdf 在不修改文件名的情况下，这里是需要的宏。

首先，重复上面的前 4 个步骤。
接下来，改为粘贴以下代码：

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

同样，点击“运行”。

宏 3：批量将 Word docx 文件转换为 PDF

首先将所有 docx 文件放在一个文件夹中。
按照上述步骤打开编辑区域。
然后粘贴下面的宏：

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

永远不要忘记单击“运行”按钮。

注意：: 在代码中“strFolder =“C：\用户\测试\桌面\测试文件\”“中，”“C：\用户\测试\桌面\测试文件\”” 是文件夹的文件路径。请记住相应地更改它。

运行此宏后，pdf 文件将保存在 Word 文档所在的同一文件夹中。

尽可能保护文件

除了预防措施外，灾后恢复受损文件也并非难事。如果您定期备份文件，找回原始文件就轻而易举。但事实上，很少有人能坚持执行备份计划，这增加了丢失宝贵数据的风险。在这种情况下，就需要借助更高级的备份工具了。 Word文档损坏修复工具.

作者简介：

Vera Chen 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括损坏的 Excel xlsx 修复和 pdf 修复软件产品。欲了解更多信息，请访问 datanumen.com