Як швидко експортувати дані про всіх членів групи контактів Outlook до Excel

За замовчуванням ви можете бачити лише імена членів та адреси електронної пошти в групі контактів. Якщо ви хочете отримати інші дані членів, ви можете скористатися способом, представленим у цій статті.

Коли ви двічі клацаєте групу контактів, щоб відкрити її, у її вікні ви можете бачити лише імена та адреси електронної пошти учасників групи. Ви не можете отримати інші дані членів, такі як компанія, назва посади, номер телефону, адреса компанії тощо. Загалом, щоб отримати ці дані, вам потрібно вручну знайти контакти, що відповідають учасникам у вашій папці “Контакти”. Це занадто клопітно. Тут ми покажемо вам фрагмент коду VBA, який може швидко експортувати ці дані до книги Excel.

Експортуйте дані про всіх членів контактної групи до Excel

1. Для початку запустіть програму Outlook.
2. Потім слід натиснути комбінації клавіш “Alt + F11” у головному вікні Outlook.
3. Далі у новому вікні “Microsoft Visual Basic for Applications” вам потрібно відкрити не використовуваний модуль або безпосередньо вставити новий модуль.
4. Згодом скопіюйте та вставте наступний код VBA в цей модуль.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Після цього для зручної перевірки ви можете додати новий проект VBA на панель швидкого доступу або стрічку.
6. Пізніше встановіть низький рівень захисту макроса Outlook.
7. Зрештою, ви можете спробувати.

• Спочатку виберіть групу контактів.
• Потім натисніть кнопку макросу на панелі швидкого доступу або стрічці.
• Відразу макрос запуститься.
• Коли він закінчиться, ви отримаєте підказку "Завершено!"
• Після цього ви можете перейти до визначеної локальної папки призначення, в якій ви зможете знайти новий файл Excel.
• Відкрийте його, ви побачите контактні дані членів групи, наприклад, наступний знімок екрана:

Не панікуйте перед проблемами Outlook

Ніхто не готовий приймати будь-які проблеми Outlook, незалежно від спливаючого повідомлення про помилку або корумпований Outlook файл даних. Тому користувачі, як правило, отримують паніку, коли стикаються з проблемами Outlook. Якщо ви хочете зберегти спокій у такому випадку, у вас повинні бути дві необхідні речі. Одним із них є поточні резервні копії даних Outlook. Інший - це потужне програмне забезпечення для виправлення Outlook, наприклад DataNumen Outlook Repair.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі відновлення SQL та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com