Як встановити різний час нагадування за замовчуванням для різних видів позначених елементів у вашому

За замовчуванням Outlook автоматично використовує час нагадування за замовчуванням про завдання для всіх видів позначених елементів. Однак, якщо ви хочете використовувати інший час нагадування для позначених елементів на основі типу товару, ви можете звернутися до методу, представленого в цій статті.

Outlook дозволяє встановити час нагадування за замовчуванням для всіх позначених елементів, незалежно від типу елементів. Ви можете зайти в меню «Файл» і натиснути «Параметри». Потім у вікні «Параметри Outlook» ви можете побачити опцію «Час нагадування за замовчуванням» на вкладці «Завдання», як показано на наступному скріншоті.

Тим не менш, більшість користувачів сподіваються використовувати різний час нагадування для різних типів позначених елементів, наприклад, «9:00» для позначених листів та «17:30» для позначених контактів. Далі ми зосередимося на цьому прикладі, щоб представити метод.

Встановіть різний час нагадування за замовчуванням для різних видів позначених елементів

1. Для початку запустіть програму Outlook.
2. Потім відкрийте редактор Outlook VBA з посиланням на “Як запустити код VBA у своєму Outlook».
3. У наступному вікні “Microsoft Visual Basic for Applications” скопіюйте наступний код у проект “ThisOutlookSession”.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Після цього перезапустіть Outlook, щоб активувати цей макрос.
5. Відтепер кожного разу, коли ви позначаєте електронний лист, час нагадування встановлюватиметься на “10:00” на день закінчення позначення.
6. І коли ви позначаєте контакт, час нагадування буде встановлено на “17:30” на дату закінчення прапора.

Вирішуйте проблеми з Outlook гнучко

Ви можете зіткнутися з різноманітними проблемами у вашому Outlook. Тому вам слід заздалегідь вивчити деякі заходи для їх вирішення. Наприклад, якщо ваш Outlook часто перезавантажується, вам потрібно відновити Office або вимкнути сторонні надбудови тощо. Або якщо ваш Outlook PST скомпрометовано, ви можете спочатку спробувати інструмент для ремонту вхідних -. Коли це не вдається, ви можете продовжувати вдаватися до потужного зовнішнього інструменту, наприклад DataNumen Outlook Repair.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі відновлення mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com