Як автоматично відкривати вкладення вхідних повідомлень електронної пошти Outlook від конкретного відправника

Якщо ви хочете, щоб Outlook автоматично відкривав вкладення вхідних листів від конкретного відправника, ви можете прочитати цю статтю. Тут ми допоможемо вам, як цього досягти.

Наприклад, ваш начальник часто надсилає вам електронного листа з декількома важливими вкладеннями файлів. Щоб якомога швидше відреагувати на свого начальника, вам потрібно відкрити вкладення, коли ви їх отримаєте. У цьому випадку вам може знадобитися розумніший спосіб дозволити Outlook автоматично відкривати вкладені вкладені файли електронної пошти від вашого начальника. Зараз ми покажемо вам такий метод.

Автоматично відкривати вкладення вхідних листів від конкретного відправника

1. Для початку запустіть програму Outlook.
2. Потім відкрийте редактор VBA за допомогою ярлика - “Alt + F11”
3. Далі вкладіть наступний код VBA у проект “ThisOutlookSession”.

Private Declare Function GetShortPathName Lib "kernel32" _
 Alias "GetShortPathNameA" (ByVal lpszLongPath As String, _
 ByVal lpszShortPath As String, ByVal cchBuffer As Long) As Long

Private WithEvents objItems As Outlook.Items

Private Sub Application_Startup()
    Set objItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new item arrives in Inbox
Private Sub objItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objWsShell As Object
    Dim strTempFolder As String
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Attachment
    Dim strFileName As String
 
    If Item.Class = olMail Then
       Set objMail = Item
       'Change sender email address
       If objMail.SenderEmailAddress = "boss@datanumen.com" Then
          Set objWShell = CreateObject("WScript.Shell")
          strTempFolder = Environ("Temp") & "\"
 
          Set objWsShell = CreateObject("WScript.Shell")
          Set objAttachments = objMail.Attachments
          If objAttachments.Count > 0 Then
             For Each objAttachment In objAttachments
                 strFileName = objAttachment.DisplayName
                 On Error Resume Next
                 Kill strTempFolder & strFileName
                 On Error GoTo 0
 
                 'Save the attachment
                 objAttachment.SaveAsFile strTempFolder & strFileName
 
                 'Open the attachment
                 strFileName = GetShortFileName(strTempFolder & strFileName)
                 On Error Resume Next
                 objWsShell.Run strFileName
             Next
          End If
        End If
    End If
End Sub

Function GetShortFileName(ByVal FullPath As String) As String
    Dim lAns As Long
    Dim sAns As String
    Dim iLen As Integer
 
    On Error Resume Next

    If Dir(FullPath) <> "" Then
       sAns = Space(255)
       lAns = GetShortPathName(FullPath, sAns, 255)
       GetShortFileName = Left(sAns, lAns)
    End If
End Function

4. Згодом закрийте редактор VBA.
5. Зрештою, перезапустіть програму Outlook, щоб активувати новий макрос.
6. Відтепер кожного разу, коли до вашої поштової скриньки надходить нове повідомлення від конкретного відправника, Outlook автоматично відкриватиме вкладення в цьому листі.

Застосувати інструмент відновлення папки "Вхідні"

Коли ваш файл даних Outlook пошкоджений, що б ви тоді робили? Насправді, по-перше, ви можете скористатися вбудованим інструментом виправлення Outlook - scanpst. Він може вирішити деякі крихітні проблеми, пов'язані з вашим Outlook. За умови, що ця утиліта виходить з ладу, настав час вдатися до набагато досвідченішого та надійнішого зовнішнього інструменту, такого як DataNumen Outlook Repair.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі пошкоджений mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com