3 швидких способи видалення порожніх рядків і стовпців у таблиці Word

У цій публікації ми розповімо вам про 3 швидких способи видалення порожніх рядків і стовпців у таблиці Word.

Таблиці важливі для документа, особливо для зберігання різних типів даних. Іноді довга таблиця може перевищувати сторінку і охоплювати кілька. Отже, коли таблиця стає довгою та складною, є заходи, які ви можете зробити, щоб її спростити. Наприклад, ви можете видалити непотрібні порожні рядки та стовпці.

Нижче наведено 3 методи, якими ви можете скористатися.

Спосіб 1: видалення порожніх рядків і стовпців вручну

1. По-перше, виділіть порожній рядок або стовпець.
2. Потім клацніть правою кнопкою миші, щоб відкрити контекстне меню. У меню виберіть відповідно «Видалити рядки» або «Видалити стовпці».

На жаль, ви не можете виділити кілька непослідовних рядків або стовпців і видалити їх разом таким чином. Для цього запиту ви можете звернутися до нашої попередньої статті: 5 швидких методів групового видалення кількох рядків або стовпців у таблиці Word

Спосіб 2: пакетне видалення всіх порожніх рядків і стовпців у таблиці

Спосіб 1 має свої обмеження. Тому ми запропонуємо вам спосіб пакетного видалення рядків і стовпців у таблиці за допомогою кодів VBA.

1. Для початку помістіть курсор всередину цільової таблиці.
2. По-друге, запустіть редактор VBA, натиснувши «Alt+ F11».
3. У редакторі спочатку клацніть «Звичайний» проект.
4. Потім клацніть на вкладці «Вставити» в рядку меню.
5. У спадному меню виберіть “Модуль”.
6. Двічі клацніть модуль, щоб відкрити його, і вставте туди такі коди:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Нарешті натисніть кнопку «Виконати» на панелі меню або натисніть «F5».

За кілька секунд ви видалите всі порожні рядки та стовпці в цій таблиці.

Спосіб 3: пакетне видалення всіх порожніх рядків і стовпців у всіх таблицях документа

1. Спочатку повторіть кроки зі способу 2, щоб установити та запустити макрос.
2. Тільки цього разу замініть цей макрос наступним:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Відновлення зламаного документа

Сьогодні існує більше, ніж просто спосіб відновити втрачені дані. Наприклад, створення резервних копій завжди залишається вашим головним пріоритетом. Якщо це не задовольняє вашу потребу в отриманні найновішої інформації, ви можете спробувати… ремонт документа інструмент.

Вступ автора:

Віра Чень є експертом з відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі ремонт xlsx та pdf ремонт програмних продуктів. Для отримання додаткової інформації відвідайте WWW.datanumen.com