2 способи групового позначення всіх електронних листів Outlook, старших за визначену дату, як прочитані

Після імпортування кількох старих електронних листів у Outlook, і ці електронні листи перебувають у стані "непрочитаного", ви повинні хотіти групово позначити їх як прочитані. Тепер у цій статті ми покажемо вам 2 швидкі методи.

Іноді вам може знадобитися групово позначати кілька електронних листів як прочитані. Наприклад, у вас є старий файл PST, який містить безліч старих листів. Потім ви імпортуєте електронні листи у власний файл Outlook PST. Однак після імпортування ці електронні листи за замовчуванням відображаються як "Непрочитані". На цей час вам потрібно буде групово позначити ці листи, старші за певну дату, як прочитані. Тут ми розглянемо цю вимогу розділити 2 зручні та ефективні підходи.

Спосіб 1: Пакетна позначка знайшла електронні листи як прочитані вручну

1. Для початку відкрийте папку пошти.
2. Потім клацніть у вікні пошуку.
3. Далі на стрічці «Пошук» натисніть кнопку «Усі поштові відправлення» в групі «Область дії».
4. Після цього введіть критерії «надіслано: <= 2018/5/21» у вікно пошуку. Змініть «2018/5/12» на бажану дату.
5. Коли пошук завершено, виберіть усі знайдені поштові відправлення за допомогою “Ctrl + A”.
6. Нарешті, клацніть правою кнопкою миші та виберіть опцію «Позначити оголошення як прочитане».

Спосіб 2: Пакетні позначки електронних листів, старших за вказану дату, як прочитані за допомогою VBA

1. Для початку запустіть редактор VBA в Outlook відповідно до “Як запустити код VBA у своєму Outlook».
2. Потім скопіюйте наступний код у модуль.

Dim dDate As Date

Sub MarkEmailsOlderThanSpecificDateRead()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    dDate = InputBox("Enter the specific date:", , "2018/5/11")
 
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
 
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If TypeOf objItem Is MailItem Then
           Set objMail = objItem
 
           If objMail.SentOn <= dDate Then
              If objMail.UnRead = True Then
                 objMail.UnRead = False
                 objMail.Save
              End If
           End If
        End If
    Next
 
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

3. Потім натисніть клавішу “F5”, щоб запустити цей макрос прямо зараз.
4. Пізніше, у маленькому діалоговому вікні, що з’явиться, введіть конкретну дату та натисніть “OK”.
5. Зрештою, усі електронні листи, старші за визначену дату, будуть позначені як прочитані.

Відновити компрометований файл Outlook

Файли Outlook PST можуть бути пошкоджені після того, як Outlook несподівано аварійно аварійно завершує роботу. Якщо у вас є оновлена ​​резервна копія, ви можете просто відновити Outlook - - дані за допомогою резервної копії. В іншому випадку вам не залишається іншого вибору, крім як звернутися до спеціаліста або утиліти, наприклад DataNumen Outlook Repair для відновлення файлу Outlook.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі виправлення mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com