Outlook'unuzda Birden Çok Kişiye Ayrı Ayrı Toplu Görev Atama

Gizlilik ya da mahremiyet gibi bazı sebeplerden dolayı bir görevi çok kişiye atarken ayrı ayrı göndermek isteyebilirsiniz. Şimdi, burada onu elde etmek için bir yöntem tanıtacağız.

Bir görev atadığınızda, birden fazla alıcı doldurup “Gönder”e tıklarsanız, çok kişiye gönderilen görevin güncellenmeyeceğine dair bir uyarı alacaksınız. Bu nedenle, görev güncellemelerini zamanında almak istiyorsanız, görevi birçok alıcıya ayrı ayrı atamanız daha iyi olur.

Tabii görev güncellemesi düşünülmesi bir yana, gizlilik gereği bir görevi birden çok kişiye ayrı ayrı göndermeniz gerekiyor. Genel olarak, ayrı görevler oluşturmanız, alıcı eklemeniz ve tek tek göndermeniz gerekir. Belli ki sıkıntılı. Bu nedenle, aşağıda size çok daha verimli bir yol tanıtacağız.

Birden Çok Kişiye Ayrı Ayrı Toplu Görev Atama

1. Öncelikle, Outlook VBA düzenleyicisine erişmek için “Alt + F11” tuşlarına basın.
2. Ardından, "Microsoft Visual Basic for Applications" penceresinde, VBA kodunu boş bir modüle veya projeye kopyalayın.

Sub AssignTaskToMultipleContactsSeparately()
    Dim objCurrentTask As Outlook.TaskItem
    Dim objRecipients As Outlook.Recipients
    Dim objRecipient As Outlook.Recipient
    Dim objCopiedTask As Outlook.TaskItem
    Dim i As Long
    Dim strRecipientName As String
 
    Set objCurrentTask = Outlook.Application.ActiveInspector.CurrentItem
 
    If Not objCurrentTask Is Nothing Then
       Set objRecipients = objCurrentTask.Recipients
 
       For Each objRecipient In objRecipients
           Set objCopiedTask = objCurrentTask.Copy
 
           For i = objCopiedTask.Recipients.Count To 1 Step -1
               objCopiedTask.Recipients.Remove (i)
           Next
 
           strRecipientName = Split(objRecipient.Address, "@")(0)
           strRecipientName = UCase(Left(strRecipientName, 1)) & Right(strRecipientName, Len(strRecipientName) - 1)
 
           With objCopiedTask
                .Recipients.Add (objRecipient.Address)
                .Recipients.ResolveAll
                .Subject = .Subject & " (" & strRecipientName & ")"
                .Assign
                .Send
          End With
        Next
 
        objCurrentTask.Close olDiscard
    End If
End Sub

3. Ardından, "İsteğe Bağlı Adım" başlıklı gönderiye atıfta bulunarak bu makroyu Görev penceresinin şeridine ekleyin.Outlook'unuzda VBA Kodunu Nasıl Çalıştırırsınız?".
4. Sonunda, bu makroyu denemek için aşağıdaki adımları izleyin.

• İlk olarak, yeni bir görev oluşturun ve istediğiniz zaman alıcıları ekleyin.
• Ardından, şeritteki makro düğmesine tıklayın.
• Bir kerede, aşağıdaki ekran görüntüsünde gösterildiği gibi, mevcut görev alıcılara ayrı ayrı atanacaktır.

Görünümünüze Dikkat Edin

Outlook, hatalara ve bozulmaya eğilimlidir. Bu nedenle, Outlook veri kaybına karşı isteksizseniz, Outlook verileriniz için düzenli yedeklemeler yapmanız gerekir. Ancak bu şekilde, Outlook dosyası bozulsa bile kolayca geri yükleyebilirsiniz. bozuk Outlook yedeklemelerden gelen veriler. Yedeklemeniz yoksa, olağanüstü ve güçlü bir kurtarma aracına başvurmanız gerekir. DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. SQL Server kurtarma ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com