Outlook'unuzdaki Güncel Olmayan Takvim Öğelerinden Ekleri Toplu Olarak Kaldırma

Outlook'unuzdaki eski randevu ve toplantılardan ekleri kaldırmak istiyorsanız, bu makaleyi okuyabilirsiniz. Burada size bunu tek seferde nasıl gerçekleştireceğinizi tanıtacağız.

Outlook dosyanızın boyutunu küçültmek için eski öğeleri temizlemeniz önemle tavsiye edilir. Bu, eski öğeleri düzenli aralıklarla otomatik olarak silebilen yerleşik "Otomatik Arşiv" özelliği ile gerçekleştirilebilir. Ancak, bazı kullanıcılar eski öğelerdeki ekleri, öğeleri kendileri etkilemeden silmek isterler. Aşağıda, eski takvim öğelerinden ekleri toplu olarak kaldırmayı size öğreteceğiz.

Eski Takvim Öğelerinden Ekleri Toplu Olarak Kaldırma

1. Başlamak için, "Alt + F11" ile Outlook VBA düzenleyicisine erişin.
2. Ardından “Microsoft Visual Basic for Applications” penceresinde VBA kodunu bir modüle kopyalayın.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Daha sonra “BatchDeleteAttachmentsOfOldCalendarItems” makrosuna tıklayın.
4. Son olarak bu makroyu çalıştırmak için “F5” tuşuna basın.
5. Makro tamamlandığında, tüm Outlook takvimlerinizi kontrol edebilirsiniz.
6. Outlook, 2 aydan eski takvim öğelerinin tüm eklerini silmiş olmalıdır.

Bozuk Outlook Dosyalarıyla Başa Çıkın

Hiç Outlook bozulmasıyla karşılaştınız mı? Genellikle nasıl elden çıkarırsınız? Çoğu zaman, önce gelen kutusu onarım aracını denersiniz – Tarama. Ancak ciddi PST hasarı durumunda yerleşik yardımcı program size yardımcı olamaz. Bu nedenle, yakınlarda daha deneyimli ve dikkat çekici bir üçüncü taraf aracı bulundurmanız önerilir. DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. sql onarımı ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com