Outlook'unuzda E-posta Adresi Olmayan Tüm Kişileri Toplu Silme Yöntemleri

Outlook'unuzda bazı kişilerin e-posta adreslerinin olmadığını fark ederseniz, bu tür tüm kişileri silmek için her Kişi klasörünü tek tek işlemden geçirmek isteyebilirsiniz. Bu yazıda size bunun için 2 yöntem paylaşacağız.

Belki de Outlook'unuzda birçok kişi vardır ve bazılarının e-posta adresi yoktur. Artık yararlı olmadıklarını düşünüyorsanız, e-posta adresi olmayan tüm kişileri silmeyi ummalısınız. Standart şekilde, onları bulmak için "Anında Arama"yı kullanabilir ve ardından aşağıdaki Yöntem 1'deki gibi manuel olarak silebilirsiniz. Yine de, biraz sıkıcı. Bu nedenle, Yöntem 2'de size daha verimli başka bir yol öğreteceğiz.

Yöntem 1: Kişileri E-posta Adresi Olmadan Bulduktan Sonra El İle Sil

1. Öncelikle, “Kişiler” paneline erişmek için “Ctrl + 3” tuşlarına basın.
2. Ardından, arama kutusuna tıklayın.
3. Ardından, ortaya çıkan "Ara" şeridinde "Tüm Kişi Öğeleri" ni tıklayın.
4. Daha sonra, “Adresi Var” > “E-posta Adresi Var”ı tıklayın.
5. Bundan sonra, arama kutusuna “NOT emailaddresses:=[]” kriteri eklenecektir. "DEĞİL" i kaldırmanız gerekir.
6. Daha sonra, e-posta adresi olmayan tüm kişiler listelenecektir.
7. Şimdi, kişi gruplarınızın da listede olması gerektiğinden, arama sonuçlarında kişileri manuel olarak seçmelisiniz.
8. Son olarak, seçilen tüm kişileri silmek için “Del” tuşuna basın.

Yöntem 2: VBA ile E-posta Adresi Olmadan Tüm Kişileri Toplu Silme

1. İlk başta, Outlook'ta VBA düzenleyicisini başlatmak için “Alt + F11” üzerine dokunun.
2. Yeni ekranda, aşağıdaki VBA kodunu bir modüle kopyalayın.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Daha sonra “BatchDeleteAllContactsWithoutEmailAddress” alt yordamına tıklayın.
4. Sonunda, bu makroyu tetiklemek için “F5” e basın.
5. Tamamlandığında, aşağıdaki resimdeki gibi sonuçlarla ilgili bir mesaj alırsınız.
6. E-posta adresi olmayan tüm kişiler "Silinmiş Öğeler" klasörüne taşındı.

Olası Tüm Risklerden Uzak Tutun

Outlook, virüsler, kullanıcı hataları, yazılım arızaları ve donanım arızaları gibi çeşitli faktörler nedeniyle zarar görebilir. Outlook zararı yaşama konusunda isteksiz olmalısınız, bu nedenle tüm bu potansiyel riskleri uzak tutmanız gerekir. Örneğin, PC'nize güçlü bir antivirüs yazılımı yüklemeniz gerekir. Ayrıca, Outlook verilerinizi düzenli olarak yedeklemeniz gerekir. Son olarak, sağlam ve güvenilir bir onarım aracı hazırlamanız daha iyi olur. DataNumen Outlook Repair. senin düzeltebilir bozuk PST kolaylıkla dosyalayın.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. SQL Server rüşvet ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com