Sözcüğünüzdeki Belirli Metni İçeren Cümleleri Bulmanın veya Silmenin 2 Hızlı Yolu

Bu yazıda, Word'ünüzde belirli bir metni içeren cümleleri bulmanın veya silmenin 2 hızlı yolunu sunacağız.

Word'de "Bul ve Değiştir" işlevini kullanarak belirli kelimelerin tüm geçişlerini kolayca bulabileceğimizi hepimiz biliyoruz. Ardından bunları vurgulamak, değiştirmek veya silmekte hiçbir sorun yaşamayacağız. Gördüğünüz gibi, hedef bir kelime veya bir kelime öbeğidir. Ancak bugün, belirli bir metni içeren cümleleri bulmanın veya silmenin makro yolunu size anlatmaktan mutluluk duyuyoruz.

Yöntem 1: Belirli Metni İçeren Cümleleri Bul veya Sil

1. Başlamak için, Word'de VBA düzenleyicisini tetiklemek için "Alt + F11" tuşlarına basın.
2. Daha sonra “Normal”e tıklayarak yeni bir modül oluşturun.
3. Ardından "Ekle"ye tıklayın ve yeni bir tane almak için "Modül"ü seçin.
4. Ve modülü çift tıklama ile açın.
5. Şimdi aşağıdaki kodları yapıştırın:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Sonra "Çalıştır" ı tıklayın.
7. Metin girmenizi isteyen bir giriş kutusu olacaktır. Tüm cümlelerin içerdiği ortak metni yazmanız yeterlidir. "Tamam"a tıklayın.
8. Ardından, seçimdeki metni içeren bir cümle ve bir mesaj kutusunun açıldığını göreceksiniz. Cümleyi silmek için “Evet”e, saklamak için “Hayır”a tıklayın.
9. Onaydan sonra, belirlenen metne sahip bir sonraki cümle seçili hale gelir. Ayrıca onay kutusu da görünür. Yani, makro sizi tüm belgeyi adım adım taramaya, hedef cümleleri bulmaya ve her seferinde onayınızı istemeye yönlendirir.

Yöntem 2: Listedeki Herhangi Bir Metni İçeren Cümleleri Bul veya Sil

Yöntem 1'deki makro ile, her seferinde yalnızca bir sözcük veya tümcecik arayabilirsiniz. Elbette, birden fazla kelime veya kelime öbeği örneği bulmak için makroyu tekrar tekrar çalıştırabilirsiniz. Çoklu arama ihtiyacını karşılamak için size başka bir makro sağlayacağız.

1. Öncelikle tüm hedef metinleri yeni bir belgeye yazın. Her bir metin parçasının, sonunda boşluk olmadan tek bir paragraf halinde yer aldığından emin olun. Belgeyi kapatın ve kaydedin.
2. Ardından, yöntem 1'deki tam adımlarla bir makro kurun ve çalıştırın.
3. Ardından makroyu bununla değiştirin:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Şimdi “Gözat” penceresi açılacaktır. Az önce kaydedilen belgeyi seçin ve “Aç”a tıklayın.
5. Aşağıdaki prosedür, yöntem 1'deki ile aynıdır.

Bozuk Belgelerle Başa Çıkma Yaklaşımı

Değerli verilerin kaybı kesinlikle yıkıcıdır. Hatta işinizi tehlikeye atabilir. Böyle bir hüsrana uğramamak için bir kelime düzeltme aracı mümkün olan en kısa sürede Böyle bir araç, belge bozulmasıyla mücadelenizi kazanmanıza yardımcı olacaktır.

Yazar Tanıtımı:

Vera Chen bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. Excel'i düzelt hem de pdf onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com