Bir Excel Çalışma Sayfasında Seçilen Hücreleri Hızlı Bir Şekilde Outlook E-postası Olarak Göndermenin 2 Yöntemi

Bazen, bir Excel çalışma sayfasındaki seçili hücreleri hızlı bir şekilde bir Outlook e-postasına eklemek ve bu e-postayı göndermek isteyebilirsiniz. Bu makale size 2 yöntem sunmak için bu dileklere bakacaktır.

Bir önceki yazım “Excel Çalışma Sayfasını Outlook E-postası Olarak Göndermenin 2 Hızlı Yöntemi” size tüm bir Excel çalışma sayfasını e-posta olarak nasıl göndereceğinizi öğretti. Ancak bazen, bir çalışma sayfasındaki seçili hücreleri yalnızca e-posta olarak göndermek istersiniz. Bu gereksinime yanıt olarak, burada size 2 yöntem göstereceğiz. Tercihinize göre herhangi birini seçebilirsiniz.

Yöntem 1: Seçilen Hücreleri E-postaya Manuel Olarak Kopyalayın

1. Öncelikle kaynak Excel dosyasını açın ve doğru Excel çalışma sayfasına erişin.
2. Ardından Outlook e-postası olarak göndermek istediğiniz hücreleri seçin.
3. Ardından, seçilen hücreleri kopyalamak için "Ctrl + C" kısayol tuşlarına basın.
4. Bundan sonra, Outlook uygulamanızı başlatın.
5. Daha sonra, yeni bir Outlook e-postası oluşturmak için “Ana Sayfa” şeridindeki “Yeni E-posta” düğmesine tıklayın.
6. Daha sonra yeni Mesaj penceresinde, mesaj gövdesi bölümüne tıklayın.
7. Ardından, önceden kopyalanan seçili Excel hücrelerini yapıştırmak için “Ctrl + V” tuş düğmelerine basın.
8. Son olarak, e-postayı her zamanki gibi oluşturabilir ve göndermek için “Gönder” düğmesine tıklayabilirsiniz.

Yöntem 2: Seçilen Hücreleri VBA ile E-posta Olarak Gönder

1. En başta, kaynak Excel çalışma kitabını açın.
2. Daha sonra Excel VBA editörüne erişmek için “Alt + F11” tuşlarına basın.
3. Yeni pencerede, yeni bir modül eklemek için “Ekle” > “Modül”e tıklayın.
4. Sonraki adımda Microsoft Outlook Nesne Kitaplığı'nı etkinleştirmeniz gerekir. "Araçlar" > "Referanslar" seçeneğine tıklayın. Açılan iletişim kutusunda "Microsoft Outlook Nesne Kitaplığı"nı bulun ve işaretleyin.
5. Ardından, aşağıdaki VBA kodunu bu modüle kopyalayın.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Sonunda, bir deneyebilirsin.

• İlk olarak, her zamanki gibi belirli hücreleri seçin.
• Ardından yeni makroya dönün ve tetiklemek için F5 tuşuna basın.
• Hemen, aşağıdaki ekran görüntüsü gibi, seçilen hücrelerin e-posta gövdesine eklendiğini görebileceğiniz yeni bir Outlook e-postası görüntülenecektir:

PST Dosyası Excel Dosyasıyla Aynı Güvenlik Açığına Sahip

Bildiğimiz gibi, Excel dosyaları ve Word belgeleri bozulmaya yatkındır. Aslında, Outlook posta kutunuzdaki tüm öğeleri içeren PST dosyası için de aynı durum geçerlidir. Bu nedenle, PST verilerinizi güvence altına almak zorlu bir iştir. En etkili önlemlerden biri, dosyayı düzenli olarak yedeklemektir. Ayrıca, acil kurtarma sağlamak için, deneyimli bir araç hazırlamanız daha iyi olur, örneğin... DataNumen Outlook Repair, yapabilen Outlook'u kurtar veriler hiç zorlanmadan.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. onarım mdf ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com