Word Belgenizden Bölümleri Çıkarmanın 2 Hızlı Yolu

Bu yazıda, Word belgenizdeki bölümleri bir veya daha fazlasına çıkarmanın 2 hızlı ve kolay yolunu sunacağız.

İçeriği bir belgeden diğerine çıkarmak oldukça sık olur. Ve önceki yazımızda, belgeden sayfaların nasıl çıkarılacağını tartıştık. Ayrıntılı bilgi için şu makaleye başvurabilirsiniz: Word Belgenizden Tek Sayfaları Çıkarmanın 2 Hızlı Yolu

Bugün size nasıl bölüm bölüm çıkarılacağını göstereceğiz.    

Yöntem 1: Geçerli Bölümü Yeni Bir Belgeye Çıkarın

1. Öncelikle imleci hedef bölüme konumlandırın.
2. Ardından, Word'de VBA düzenleyicisini çağırmak için “Alt + F11” tuşlarına basın.
3. Ardından sol sütunda “Normal” üzerine tıklayın.
4. Ve menü çubuğunda, "Ekle" yi tıklayın.
5. Ardından, bu açılır menüden “Modül” seçeneğini seçin.
6. Yeni modülü açmak için çift tıklayın ve aşağıdaki kodları oraya yapıştırın:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Ardından, menü çubuğundaki "Çalıştır"a tıklayın veya "F5"e basın.
8. Ardından “Gözat” penceresi açılacaktır. Yeni belgeyi saklamak için bir yer seçin ve "Tamam"a tıklayın.
9. Ve "Dosya Adı" kutusuna yeni dosyanın adını girin ve "Tamam" ı tıklayın.

Şimdi bölümü yeni bir belgeye çıkardınız.

Yöntem 2: Belgedeki Her Bölümü Ayrı Ayrı Yeni Bölümlere Ayıkla

Bu yol, bir belgedeki tüm bölümleri toplu olarak işlemenize yardımcı olabilir. Elbette bir makroya da ihtiyacımız olacak.

1. Öncelikle hedef belgeyi açın.
2. Ardından, bir makro yüklemek ve çalıştırmak için yöntem 1'deki adımları izleyin.
3. Ancak bu sefer o makroyu bununla değiştirin:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Yine de, "Gözat" penceresinde bir depolama yolu seçin ve "Tamam"a tıklayın.

Rahatsız Edici Kelime Hatalarını Düzeltin

Kullanırken bazı Word hatalarıyla karşılaşmak yaygındır. Sinir bozucu olabilir, zaman ayırmalıyız kelimeyi kurtarmak mümkün olan en kısa sürede. Çünkü ne kadar geciktirirsek, veri kaybı o kadar ciddi olabilir. Bu nedenle, önceden bir onarım aracı bulmanız önerilir.

Yazar Tanıtımı:

Vera Chen bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. bozuk xls hem de pdf onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com