Word Belgenizden Tek Sayfaları Çıkarmanın 2 Hızlı Yolu

Bugünkü yazımızda, Word belgenizden tek tek sayfaları ayıklamanın 2 hızlı yolunu sizlerle paylaşmak istiyoruz.

Bazen bir Word belgesinde, her sayfa tablo gibi oldukça bağımsız içerikler içerebilir. Ve muhtemelen farklı kişilere farklı tablolar göndermeniz gerekecektir. Ardından, her sayfa olan her tabloyu ayrı bir dosya olarak kaydetmeniz gerekecektir.

Aklımıza gelen ilk fikir klasik kopyala ve yapıştır olmalıdır. Yine de, seçim içeren herhangi bir şey bazen can sıkıcı olabilir, çünkü sürükleyip seçmek, hiç seçim yapmadan bir ucu kolayca yapabilir. Bu nedenle, işi yapmak için makro kullanarak size 2 hızlı yöntem öneriyoruz.

Yöntem 1: Geçerli Sayfayı Çıkarın ve Yeni Belge Olarak Kaydedin

1. Öncelikle, imlecinizi veri çıkarmak istediğiniz sayfaya konumlandırın.
2. "Geliştirici" sekmesine tıklayın ve ardından VBA düzenleyicisini çağırmak için "Visual Basic"e tıklayın. "Geliştirici" etkinleştirilmemişse, bunun yerine "Alt + F11" tuşlarına basmanız yeterlidir.
3. İkinci olarak, üzerine tıklayarak “Normal” projesine gidin.
4. Ardından “Ekle” sekmesine tıklayın ve “Modül” seçeneğini seçin.
5. Düzenleme alanını açmak için yeni modüle çift tıklayın.
6. Ardından aşağıdaki kodları oraya yapıştırın:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Son olarak, “Çalıştır” düğmesine tıklayın.

Şimdi 2 giriş kutusu olacak. İlk giriş kutusuna yeni belgeyi saklamak istediğiniz yolu girin. Ve ikincisine yeni belge adını girin.

Yöntem 2: Her Sayfayı Ayıkla ve Yeni Bir Belge Olarak Kaydet

Aşağıdaki makro, bir belgenin her bir sayfasını ayrı ayrı ayıklamanıza olanak tanır.

1. İlk olarak, belgenizin en başına gitmek için “Ctrl+Home” tuşlarına basın.
2. Ardından, bir makro yüklemek ve çalıştırmak için yöntem 1'deki aynı adımları izleyin.
3. Bu sefer makroyu bununla değiştirin:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Kelime Sorunlarıyla Başa Çıkın

Word'de her zaman çeşitli sorunlar olmuştur ve olacaktır. Önemli olan bunları doğru şekilde düzeltmeyi öğrenmektir. En çok önerilen yöntem ise elbette gelişmiş bir Word programı edinmektir. Kelime kurtarma alet. Çok geç olmadan verilerinizi kurtarmak için her dakikayı değerlendirmelisiniz.

Yazar Tanıtımı:

Vera Chen bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. bozuk xlsx hem de pdf onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com