3 Mga Paraan upang Makakuha ng Mga Istatistika ng Pagbibilang ng Salita na Kaugnay sa Mga Kahon ng Teksto, Mga Talababa at Tala ng Tala sa iyong Dokumento

Sa artikulong ngayon, mayroong 3 mabilis na paraan upang makakuha ng mga istatistika ng bilang ng salita na nauugnay sa mga text box, footnote at endnote sa iyong dokumento.

Hindi mahirap makuha ang kabuuang bilang ng mga salita sa isang dokumento. Ngunit kung gusto mong makuha ang bilang ng mga salita ng iba't ibang uri ng mga teksto, kakailanganin ng higit pang mga operasyon. Ang sumusunod ay 3 pamamaraan. Magbasa para makita kung ano ang maaari mong gamitin. 

Paraan 1: Bilangin ang mga Salita Kabilang ang mga Teksto mula sa Mga Text Box, Footnote at Endnote

Bilang default, binibilang ng Word ang lahat ng mga salita na lilitaw sa dokumento, kabilang ang mga teksto sa mga text box at mga salita mula sa mga footnote at endnote pati na rin.

1. Una sa lahatost, pumunta sa status bar at i-click ang “Words” para buksan ang “Word Count” box.
2. Doon mo makikita ang lahat ng uri ng istatistika. Tiyaking nilagyan mo ng check ang kahon na "Isama ang mga textbox, footnote at endnote."
3. Pagkatapos ay i-click ang "Isara".
4. Kung hindi mo mahanap ang command na "Words" sa status bar, i-right click doon.
5. Susunod na suriin ang "Word Count".

Paraan 2: Ibukod ang Mga Teksto mula sa Mga Text Box, Footnote at Endnote mula sa Word Count

Ito ay kabaligtaran ng paraan 1. Kaya kailangan mo lang alisan ng tsek ang kahon na "Isama ang mga textbox, footnote at endnote".

Paraan 3: Patakbuhin ang Word Macro upang Kumuha ng Hiwalay na Bilang ng mga Salita mula sa Mga Text Box, Footnote at Endnote

1. Una, i-trigger ang "Word Count" na kahon gamit ang paraan sa paraan 1 at tiyaking may check ang option box.
2. Susunod na pindutin ang "Alt + F11" upang buksan ang VBA editor.
3. Pagkatapos ay magpasok ng bagong module sa "Normal" na proyekto sa pamamagitan ng pag-click muna sa "Normal".
4. At i-click ang "Ipasok" sa susunod.
5. Piliin ang "Module" pagkatapos.
6. I-double click ang module upang buksan ang coding area at i-paste ang mga sumusunod na code doon:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Panghuli, i-click ang pindutang "Run".

Kung walang text box, footnote o endnote, makakatanggap ka ng message box gaya nito:

I-click lamang ang "OK" upang magpatuloy. Pagkatapos ay makakakita ka ng isa pang kahon, na naglilista ng lahat ng mga detalye ng bilang ng salita.

Kumuha ng Tool sa Pagbawi

Dahil maaaring biglang bumagsak ang Word, ipinapayong kumuha ng advanced na produkto sa pag-aayos upang magawa ang pag-aayos. Ang ganitong tool ay maaaring maging isang mahusay na saver para sa masamang Salita. Samakatuwid, samantalahin ang oras upang makakuha ng isa sa lalong madaling panahon.

Panimula ng May-akda:

Si Vera Chen ay isang dalubhasa sa pagbawi ng data sa DataNumen, Inc., na pinuno ng mundo sa mga teknolohiya sa pagbawi ng data, kasama ang ayusin ang xls at pdf pagkumpuni ng mga produktong software. Para sa karagdagang impormasyon pagbisita www.datanumen. Sa