วิธีการส่งออกอย่างรวดเร็วรวมเวลาที่ใช้ในการนัดหมาย Outlook ในแต่ละประเภทสี

หากคุณต้องการสร้างรายงานเกี่ยวกับเวลาทั้งหมดที่คุณใช้ในการนัดหมายในแต่ละประเภทสีคุณสามารถใช้วิธีการที่แนะนำในบทความนี้ สามารถช่วยให้คุณทำสิ่งนี้ได้สำเร็จในเวลาอันรวดเร็วโดยไม่จำเป็นต้องนับด้วยตนเอง

ผู้ใช้หลายคนคุ้นเคยกับการบันทึกกิจกรรมส่วนใหญ่ลงในปฏิทิน Outlook และเพื่อจัดการและแยกแยะกิจกรรมเหล่านั้นได้ง่ายขึ้น พวกเขาจึงกำหนดหมวดหมู่ให้กับแต่ละรายการ ในกรณีนี้ ผู้ใช้บางคนต้องการสร้างรายงานที่แสดงเวลาทั้งหมดที่ใช้ไปกับรายการในปฏิทินแต่ละหมวดหมู่สี แน่นอนว่าการนับและป้อนข้อมูลด้วยตนเองนั้นยุ่งยาก ดังนั้นในที่นี้เราจะแบ่งปันวิธีการที่สามารถทำงานนี้ให้สำเร็จได้ด้วยการคลิกเพียงครั้งเดียว

ส่งออกเวลาทั้งหมดที่ใช้ในการนัดหมายในแต่ละประเภทสี

1. ในตอนแรกเปิดแอปพลิเคชัน Outlook ของคุณ
2. จากนั้นหลังจากเข้าสู่หน้าต่าง Outlook คุณสามารถแตะที่ปุ่ม "Alt + F11"
3. จากนั้นคุณจะสามารถเข้าถึงหน้าต่าง“ Microsoft Visual Basic for Applications”
4. ขั้นตอนต่อไป คุณจะต้องเปิดใช้งาน “Microsoft Excel Object Library” โดยคลิกที่ “เครื่องมือ” > “การอ้างอิง” เพื่อดำเนินการดังกล่าว
5. จากนั้นคุณควรค้นหาและเปิดโมดูลที่ไม่ได้ใช้งาน
6. หลังจากนั้นคุณต้องคัดลอกรหัส VBA ต่อไปนี้ลงในโมดูลนี้

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. ในที่สุดคุณก็สามารถเรียกใช้มาโครนี้ไม่ว่าจะผ่านการคลิกไอคอน "เรียกใช้" ในแถบเครื่องมือหรือกดปุ่ม "F5"
8. จากนั้นคุณจะต้องเลือกปฏิทินที่ต้องการ
9. หลังจากที่คุณเลือกและกด "ตกลง" มาโครจะยังคงทำงานต่อไป หลังจากเสร็จสิ้นจะมีไฟล์ Excel ใหม่ที่แสดงในพื้นหลัง
10. คุณสามารถเข้าถึงได้ จะมีลักษณะเหมือนภาพหน้าจอต่อไปนี้:

ระวังภัยคุกคามที่อาจเกิดขึ้นรอบ ๆ Outlook ของคุณ

ผู้ใช้ Outlook ควรระวังความเสี่ยงที่อาจเกิดขึ้นทั้งหมดรวมถึงไฟล์แนบอีเมลที่ไม่รู้จักลิงก์ที่ฝังไว้และข้อผิดพลาดจากมนุษย์ มิฉะนั้น Outlook ของคุณอาจเสียหายได้ตลอดเวลา นอกจากนี้การสำรองข้อมูล Outlook เป็นประจำและการเก็บรักษาเครื่องมือซ่อมแซมเฉพาะก็เป็นเรื่องที่จำเป็น DataNumen Outlook Repair เป็นหนึ่งในเครื่องมือแก้ไขที่ได้รับการแนะนำมากที่สุด มันสามารถ ซ่อมแซม Outlook ปัญหาในระยะเวลาอันสั้น

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ mdf เสียหาย และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.