วิธีการส่งออกอีเมล Outlook อย่างรวดเร็วเป็นไฟล์รูปภาพ

ผู้ใช้บางรายต้องการส่งออกอีเมล Outlook เป็นไฟล์รูปภาพเช่นไฟล์ jpg ดังนั้นในบทความนี้เราจะแนะนำวิธีรับผ่านรหัส Outlook VBA

คุณต้องเรียนรู้เทคนิคต่างๆในการส่งออกอีเมลเป็นไฟล์ข้อความเอกสาร Word และอื่น ๆ แล้วการส่งออกอีเมลเป็นรูปภาพเช่นไฟล์ JPG ล่ะ? เห็นได้ชัดว่า Outlook ไม่มีฟังก์ชันนี้ แต่หลังจากนั้นเราจะแบ่งปันวิธีการสั้น ๆ กับคุณ

ส่งออกอีเมล Outlook อย่างรวดเร็วเป็นไฟล์รูปภาพ

1. สำหรับเป็นtart เปิดแอปพลิเคชัน Outlook ของคุณ
2. จากนั้นในหน้าต่างหลักของ Outlook ให้เข้าถึงโปรแกรมแก้ไข VBA ตามบทความ -“วิธีเรียกใช้รหัส VBA ใน Outlook ของคุณ"
3. จากนั้นเปิดใช้งาน“ MS Word Object Library” และ“ MS PowerPoint วัตถุ Library” โดยอ้างถึงบทความ -“วิธีเพิ่ม Object Library การอ้างอิงใน VBA"
4. จากนั้นคัดลอกและวางรหัส VBA ต่อไปนี้ลงในโมดูลเปล่า

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. หลังจากนั้นคุณต้องเพิ่มมาโครลงในแถบเครื่องมือด่วน
6. จากนั้นคุณสามารถปิดตัวแก้ไข VBA
7. จากนั้นเลือกอีเมลและกดปุ่มมาโครในแถบเครื่องมือด่วน
8. เมื่อมาโครเสร็จสมบูรณ์คุณสามารถไปที่โฟลเดอร์ภายในเครื่องที่กำหนดไว้ล่วงหน้าเพื่อค้นหาไฟล์ภาพที่ส่งออกจากอีเมลนี้

ดึงข้อมูล Outlook จากไฟล์ที่เสียหาย

คุณอาจจะค่อนข้างหงุดหงิดหากไฟล์ Outlook ของคุณได้รับความเสียหายอย่างรุนแรง ในสถานการณ์นั้นคุณจะดำเนินการแยกข้อมูล Outlook จากไฟล์ที่ถูกบุกรุก ผู้ใช้บางคนมักจะใช้ประโยชน์จากเครื่องมือซ่อมแซมกล่องจดหมาย กระนั้นมost เวลาจะไม่สร้างผลกระทบ ดังนั้นคุณควรรักษาความน่าเกรงขามและน่าเชื่อถือไว้ดีกว่า PST แก้ไข เครื่องมือเช่น DataNumen Outlook Repair. สามารถสแกนไฟล์ที่เสียหายและรับข้อมูลกลับมาได้สูงสุดโดยไม่ต้องยุ่งยาก

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ แก้ไข mdf และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.