วิธีส่งออกรายละเอียดของสมาชิกทั้งหมดในกลุ่มที่ติดต่อ Outlook ไปยัง Excel อย่างรวดเร็ว

ตามค่าเริ่มต้น คุณจะเห็นเฉพาะชื่อสมาชิกและที่อยู่อีเมลในกลุ่มที่ติดต่อเท่านั้น หากคุณต้องการทราบรายละเอียดอื่นๆ ของสมาชิก คุณสามารถใช้วิธีที่แนะนำในบทความนี้

เมื่อคุณคลิกสองครั้งที่กลุ่มที่ติดต่อเพื่อเปิด ในหน้าต่าง คุณจะเห็นเฉพาะชื่อและที่อยู่อีเมลของสมาชิกกลุ่มเท่านั้น คุณไม่สามารถรับรายละเอียดอื่นๆ ของสมาชิกได้ เช่น บริษัท ตำแหน่งงาน หมายเลขโทรศัพท์ หรือที่อยู่ธุรกิจ เป็นต้น โดยทั่วไป ในการรับรายละเอียดเหล่านี้ คุณต้องค้นหาผู้ติดต่อที่เกี่ยวข้องกับสมาชิกในโฟลเดอร์ผู้ติดต่อของคุณด้วยตนเอง มันลำบากเกินไป ที่นี่เราจะแสดงโค้ด VBA ให้คุณเห็น ซึ่งสามารถส่งออกรายละเอียดเหล่านี้ไปยังสมุดงาน Excel ได้อย่างรวดเร็ว

ส่งออกรายละเอียดของสมาชิกทั้งหมดในกลุ่มที่ติดต่อไปยัง Excel

1. ขั้นแรก ให้เปิดแอปพลิเคชัน Outlook ของคุณ
2. จากนั้นคุณควรกดคีย์ลัด “Alt + F11” ในหน้าต่าง Outlook หลัก
3. ถัดไปในหน้าต่าง "Microsoft Visual Basic for Applications" ใหม่ คุณต้องเปิดโมดูลที่ไม่ได้ใช้งานหรือแทรกโมดูลใหม่โดยตรง
4. จากนั้นคัดลอกและวางโค้ด VBA ต่อไปนี้ลงในโมดูลนี้

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. หลังจากนั้น เพื่อความสะดวกในการตรวจสอบ คุณสามารถเพิ่มโครงการ VBA ใหม่ไปยัง Quick Access Toolbar หรือ Ribbon
6. ภายหลังตั้งค่าระดับความปลอดภัยของแมโคร Outlook เป็นต่ำ
7. ในที่สุดคุณสามารถลอง

• ขั้นแรก เลือกกลุ่มผู้ติดต่อ
• จากนั้นกดปุ่มมาโครใน Quick Access Toolbar หรือ Ribbon
• มาโครจะทำงานทันที
• เมื่อเสร็จสิ้น คุณจะได้รับข้อความว่า “เสร็จสมบูรณ์!”
• หลังจากนั้น คุณสามารถไปที่โฟลเดอร์ในเครื่องปลายทางที่กำหนดไว้ล่วงหน้า ซึ่งคุณจะพบไฟล์ Excel ใหม่
• เปิดขึ้นมา คุณจะเห็นรายละเอียดการติดต่อของสมาชิกกลุ่มดังภาพหน้าจอต่อไปนี้:

อย่าตื่นตระหนกเมื่อเผชิญกับปัญหา Outlook

ไม่มีใครเต็มใจที่จะยอมรับปัญหาใด ๆ ของ Outlook ไม่ว่าจะเป็นข้อความแสดงข้อผิดพลาดป๊อปอัปหรือ Outlook เสียหาย แฟ้มข้อมูล. ดังนั้นผู้ใช้มักจะตื่นตระหนกเมื่อเจอปัญหาของ Outlook หากคุณต้องการสงบสติอารมณ์ในกรณีนี้ คุณควรมีสิ่งจำเป็นสองอย่างอยู่ในมือ หนึ่งคือการสำรองข้อมูล Outlook ปัจจุบัน อีกอันหนึ่งคือซอฟต์แวร์แก้ไข Outlook ที่มีศักยภาพเช่น DataNumen Outlook Repair.

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ การกู้คืน sql และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.