วิธีแนบไฟล์ที่แก้ไขล่าสุดอย่างรวดเร็วในโฟลเดอร์ Windows กับอีเมล Outlook ของคุณ

โซลูชัน Outlook September 29, 2025

ในบางครั้งคุณอาจต้องการค้นหาและแนบไฟล์ที่แก้ไขล่าสุดในโฟลเดอร์ Windows ที่ต้องการไปยังอีเมล Outlook อย่างรวดเร็ว ในกรณีนี้คุณสามารถใช้วิธีการที่แนะนำในบทความนี้

ผู้ใช้บางรายต้องการให้ Outlook ค้นหาและเพิ่มไฟล์ที่แก้ไขล่าสุดในโฟลเดอร์ของ Windows ลงในอีเมลอย่างรวดเร็ว เช่น ไฟล์ที่สร้าง แก้ไข หรือบันทึกใหม่ล่าสุด อย่างไรก็ตาม Outlook ไม่มีฟีเจอร์ดังกล่าวโดยตรง ดังนั้น ในส่วนต่อไปนี้ เราจะแสดงโค้ด VBA ที่สามารถทำให้สิ่งนี้เกิดขึ้นได้ง่ายๆ

แนบไฟล์ที่แก้ไขล่าสุดในโฟลเดอร์ Windows กับอีเมล

ในตอนแรกคุณควรเปิดแอปพลิเคชัน Outlook ของคุณ
จากนั้นหลังจากเข้าสู่หน้าต่างหลักของ Outlook แล้วคุณสามารถกดปุ่ม“ Alt + F11”
ถัดไปคุณจะเข้าถึงหน้าต่างตัวแก้ไข Outlook VBA ได้สำเร็จ
จากนั้นคุณควรค้นหาและเปิดโมดูลที่ไม่ได้ใช้งาน
จากนั้นคัดลอกและวางโค้ด VBA ต่อไปนี้ลงในหน้าต่างโมดูลนี้

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

หลังจากนั้นคุณสามารถออกจากหน้าต่างตัวแก้ไข VBA ปัจจุบันและดำเนินการเพิ่มมาโครใหม่ในแถบเครื่องมือด่วนหรือริบบิ้นของหน้าต่างข้อความ
ในภายหลังคุณต้องเปลี่ยนระดับความปลอดภัยของแมโคร Outlook เป็นระดับต่ำ
ในที่สุดคุณสามารถลอง

ประการแรกสร้างและเขียนอีเมล Outlook ใหม่ตามปกติ
จากนั้นกดปุ่มมาโครในแถบเครื่องมือด่วนดังภาพด้านล่าง:
ถัดไปคุณจะต้องเลือกโฟลเดอร์ Windows ต้นทางและกด "ตกลง"
หากมีไฟล์ดังกล่าวในโฟลเดอร์ Windows ที่เลือกคุณจะได้รับข้อความแจ้งเหมือนภาพหน้าจอต่อไปนี้:
เมื่อคุณกด "ใช่" ไฟล์นี้จะถูกแนบพร้อมกัน

แก้ไขปัญหา Outlook โดยเร็วที่สุด

เมื่อใดก็ตามที่คุณพบปัญหาเกี่ยวกับ Outlook ขอแนะนำให้แก้ไขโดยเร็วที่สุด ในสถานการณ์เช่นนี้คุณควรเตรียมความพร้อม แก้ไข Outlook เครื่องมือล่วงหน้าเช่น DataNumen Outlook Repair. สามารถแก้ไขข้อผิดพลาด PST และกู้คืนข้อมูล Outlook ของคุณได้อย่างมีประสิทธิภาพ

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ mdf เสียหาย และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.