วิธีการใช้บรรทัดแรกของเนื้อหาเป็นหัวเรื่องโดยอัตโนมัติก่อนที่จะส่งอีเมล Outlook โดยไม่มีหัวเรื่อง

ผู้ใช้บางรายต้องการให้ Outlook ใช้บรรทัดแรกของเนื้อหาอีเมลเป็นหัวเรื่องโดยอัตโนมัติเมื่อส่งอีเมลที่ไม่มีหัวเรื่อง ในบทความนี้ เราจะแนะนำวิธีการรับรู้ผ่านโค้ด VBA

ผู้ใช้หลายคนมักลืมใส่หัวเรื่องเมื่อเขียนและส่งอีเมล ดังนั้น โดยปกติแล้ว พวกเขาหวังว่า Outlook จะสามารถเติมหัวเรื่องตามบรรทัดแรกของเนื้อหาอีเมลได้โดยอัตโนมัติ หากอีเมลขาออกไม่มีหัวเรื่อง หลังจากนั้นเราจะแบ่งปันวิธีที่ง่ายและสะดวกให้กับคุณ

ใช้บรรทัดแรกของเนื้อหาเป็นหัวเรื่องโดยอัตโนมัติก่อนที่จะส่งอีเมลโดยไม่มีหัวเรื่อง

1. เริ่มแรกให้เปิดแอปพลิเคชัน Outlook
2. จากนั้นให้ทำตามขั้นตอนใน “วิธีเรียกใช้รหัส VBA ใน Outlook ของคุณ“ คุณสามารถเข้าสู่โปรแกรมแก้ไข VBA ได้
3. จากนั้น ในตัวแก้ไข VBA ให้เพิ่มการอ้างอิงถึง “MS Word Object Library” ตาม“วิธีเพิ่ม Object Library การอ้างอิงใน VBA"
4. หลังจากนั้น ให้คัดลอกโค้ดด้านล่างลงในโปรเจ็กต์ “ThisOutlookSession”

Private WithEvents objInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail And Inspector.CurrentItem.Subject = "" Then
       Inspector.CurrentItem.Subject = " "
    End If
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objMailSelection As Word.Selection
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       If Len(Trim(objMail.Subject)) = 0 Then
          If MsgBox("No subject! Whether to take first line as subject?", vbQuestion + vbYesNo) = vbYes Then
             Set objMailDocument = objMail.GetInspector.WordEditor
             Set objMailSelection = objMailDocument.Application.Selection
 
             objMailDocument.Range(0, 0).Select
             objMailSelection.MoveEnd wdLine
 
             'Take first line of body as subject
             objMail.Subject = objMailSelection.Text
          End If
       End If
     End If
End Sub

5. หลังจากนั้นให้วางเคอร์เซอร์ไปที่ “Application_Starรูทีนย่อย tup” แล้วกด“ F5”
6. สุดท้ายคุณสามารถลอง

• ขั้นแรก ให้สร้างและเขียนอีเมลโดยเว้นหัวข้อว่างไว้
• จากนั้นคลิกปุ่ม "ส่ง"
• หลังจากนั้น คุณจะได้รับข้อความถามว่าจะใช้บรรทัดแรกของเนื้อหาเป็นหัวเรื่องหรือไม่
• ตราบใดที่คุณเลือกปุ่ม "ใช่" บรรทัดแรกของเนื้อหาอีเมลจะถูกแยกและใช้เป็นหัวเรื่อง และอีเมลจะถูกส่งออกไป

รักษาข้อมูล Outlook ของคุณให้ปลอดภัย

แน่นอนว่ามีอีเมลสำคัญหลายฉบับและรายการอื่นๆ ใน Outlook ของคุณ ดังนั้น คุณจะต้องไม่เต็มใจที่จะเจอข้อมูลสูญหายของ Outlook จากนั้น คุณจะต้องดำเนินการบางอย่าง เช่น สำรองข้อมูล Outlook ของคุณเป็นประจำ เรียนรู้การใช้เครื่องมือซ่อมแซมในตัวเพื่อ แก้ไข Outlook ข้อผิดพลาดและการเตรียมยูทิลิตี้การกู้คืนภายนอกที่มีประสิทธิภาพ DataNumen Outlook Repair เป็นตัวเลือกที่ดีเนื่องจากมีอัตราการฟื้นตัวของ PST สูง

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ การกู้คืน sql และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.