วิธีการแบทช์ส่งแผ่นงานทั้งหมดในสมุดงาน Excel หนึ่งชุดเป็นอีเมล Outlook แยกกัน

โซลูชัน Outlook September 29, 2025

หากคุณต้องการส่งแผ่นงานทั้งหมดในสมุดงาน Excel เป็นอีเมล Outlook แยกกันคุณสามารถใช้วิธีการที่แนะนำในบทความนี้ สามารถแนะนำให้คุณตระหนักถึงจำนวนมากได้โดยไม่ต้องส่งทีละรายการให้ยุ่งยาก

ในโพสต์ก่อนหน้านี้ของฉัน “2 วิธีด่วนในการส่งแผ่นงาน Excel เป็นอีเมล Outlookในบทความก่อนหน้านี้ คุณจะได้เรียนรู้สองวิธีในการส่งเวิร์กชีต Excel หนึ่งแผ่นเป็นอีเมล หากคุณต้องการส่งเวิร์กชีตทั้งหมดในเวิร์กบุ๊กเดียวเป็นอีเมลแยกกัน การใช้วิธีใดวิธีหนึ่งที่กล่าวถึงในบทความนั้นจะค่อนข้างยุ่งยากและเสียเวลา ดังนั้น ในที่นี้เราจะแนะนำอีกวิธีหนึ่งซึ่งสามารถทำการ "ส่งแบบกลุ่ม" ได้อย่างรวดเร็ว

Batch ส่งแผ่นงานทั้งหมดในสมุดงาน Excel หนึ่งชุดเป็นอีเมลแยกกัน

ในตอนแรกคุณควรเปิดเวิร์กบุ๊ก Excel ต้นทาง
จากนั้นหลังจากเข้าสู่หน้าต่าง Excel คุณควรแตะที่ปุ่มลัด“ Alt + F11”
จากนั้นหน้าต่างอื่นที่เรียกว่า“ Microsoft Visual Basic for Applications” จะปรากฏขึ้น
ในนั้นคุณต้องเปิดโมดูลที่ไม่ได้ใช้งานหรือใส่โมดูลใหม่
จากนั้นคุณสามารถคัดลอกโค้ด VBA ต่อไปนี้ลงในโมดูลนี้

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

หลังจากนั้นคุณสามารถเรียกใช้มาโครนี้ได้โดยกดปุ่ม F5 หรือคลิกไอคอน "เรียกใช้" ในแถบเครื่องมือ
ในครั้งเดียวอีเมลซึ่งสอดคล้องกับแผ่นงานทั้งหมดในสมุดงาน Excel นี้จะแสดงใน Outlook
สุดท้ายคุณสามารถตรวจสอบรายละเอียดอีเมลทั้งหมดอีกครั้งและสุดท้ายคลิกปุ่ม "ส่ง" เพื่อส่งอีเมลออกไป

ใช้เครื่องมือการกู้คืนที่มีศักยภาพหากไม่มีการสำรองข้อมูล

ผู้ใช้จำนวนมากขึ้นเข้าใจถึงความสำคัญของการสำรองข้อมูล ตราบใดที่คุณสำรองไฟล์ PST ไว้ การกู้คืน PST หลังจากความเสียหายจะค่อนข้างง่าย แต่ถ้าไม่มีการสำรองข้อมูล PST ที่มีประสิทธิภาพและเป็นปัจจุบันคุณไม่มีทางเลือกอื่นนอกจากใช้เครื่องมือซ่อมแซม PST ภายนอกเช่น DataNumen Outlook Repair. สามารถซ่อมแซมไฟล์ PST ที่ถูกบุกรุกได้อย่างง่ายดาย

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้คืน sql และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.