วิธีการ Batch ลบไฟล์แนบออกจากรายการปฏิทินที่ล้าสมัยใน Outlook ของคุณ

หากคุณต้องการลบสิ่งที่แนบมาจากการนัดหมายและการประชุมที่ล้าสมัยใน Outlook ของคุณคุณสามารถอ่านบทความนี้ได้ ที่นี่เราจะแนะนำวิธีการตระหนักรู้ในครั้งเดียว

ในการลดขนาดไฟล์ Outlook ของคุณขอแนะนำอย่างยิ่งให้ล้างรายการเก่า สิ่งนี้สามารถรับรู้ได้จากคุณสมบัติ“ การเก็บถาวรอัตโนมัติ” ในตัวซึ่งสามารถลบรายการเก่าโดยอัตโนมัติในช่วงเวลาปกติ อย่างไรก็ตามผู้ใช้บางรายต้องการลบไฟล์แนบในรายการเก่าโดยไม่ส่งผลกระทบต่อรายการนั้น ๆ ในสิ่งต่อไปนี้เราจะสอนให้คุณลบไฟล์แนบจำนวนมากออกจากรายการปฏิทินเก่า

Batch ลบไฟล์แนบออกจากรายการปฏิทินที่ล้าสมัย

1. ในการเริ่มต้นให้เข้าถึงโปรแกรมแก้ไข Outlook VBA โดย“ Alt + F11”
2. จากนั้นในหน้าต่าง“ Microsoft Visual Basic for Applications” คัดลอกโค้ด VBA ลงในโมดูล

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. หลังจากนั้นคลิกในมาโคร“ BatchDeleteAttachmentsOfOldCalendarItems”
4. ในที่สุดให้กดปุ่ม "F5" เพื่อเรียกใช้มาโครนี้
5. เมื่อแมโครเสร็จสมบูรณ์คุณสามารถตรวจสอบปฏิทิน Outlook ทั้งหมดของคุณได้
6. Outlook ต้องลบสิ่งที่แนบทั้งหมดของรายการปฏิทินที่มีอายุมากกว่า 2 เดือน

จัดการกับไฟล์ Outlook ที่เสียหาย

คุณเคยพบความเสียหายของ Outlook หรือไม่? โดยปกติคุณจะกำจัดมันอย่างไร? บ่อยกว่านั้นคุณต้องลองใช้เครื่องมือซ่อมแซมกล่องจดหมายก่อน - scanpst. แต่ในกรณีที่ PST เสียหายร้ายแรงยูทิลิตี้ในตัวไม่สามารถช่วยคุณได้ ดังนั้นจึงขอแนะนำให้เก็บเครื่องมือของบุคคลที่สามที่มีประสบการณ์และน่าทึ่งไว้ในบริเวณใกล้เคียงเช่น DataNumen Outlook Repair.

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ ซ่อม sql และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.