วิธีใช้หมวดหมู่ของอีเมลโดยอัตโนมัติกับการตอบกลับและส่งต่อทั้งหมดใน Outlook

เมื่อตอบกลับหรือส่งต่ออีเมล คุณอาจต้องการใช้หมวดหมู่เดียวกัน ในบทความนี้ เราจะสอนให้คุณเข้าใจสิ่งนี้ด้วยโค้ด VBA

หากคุณคุ้นเคยกับการกำหนดหมวดหมู่สีเดียวกันของอีเมลต้นฉบับให้กับการตอบกลับและส่งต่อทั้งหมด เหตุใดคุณจึงไม่ปล่อยให้ Outlook ดำเนินการโดยอัตโนมัติ แม้ว่า Outlook จะไม่ได้จัดเตรียมคุณลักษณะดังกล่าวโดยตรง แต่คุณยังคงได้รับความช่วยเหลือจากโค้ด VBA ต่อไปนี้ เราจะเปิดเผยขั้นตอนโดยละเอียดและโค้ดให้คุณทราบ

ใช้หมวดหมู่ของอีเมลโดยอัตโนมัติกับการตอบกลับและส่งต่อทั้งหมด

1. เริ่มแรกให้เปิดแอปพลิเคชัน Outlook
2. จากนั้นกดแป้น “Alt + F11” เพื่อเรียกใช้โปรแกรมแก้ไข Outlook VBA
3. จากนั้นคัดลอกโค้ด VBA ต่อไปนี้ลงในโปรเจ็กต์“ ThisOutlookSession”

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. หลังจากนั้น ให้รีสตาร์ท Outlook เพื่อเปิดใช้งานโปรเจ็กต์นี้
5. ตั้งแต่นั้นมา คุณสามารถลองทำตามขั้นตอนด้านล่าง

• ก่อนอื่น เลือกอีเมลแล้วกดปุ่ม “ส่งต่อ”
• จากนั้น อีเมลส่งต่อจะปรากฏขึ้น ซึ่งคุณสามารถเปลี่ยนไปที่แท็บ "ตัวเลือก" และกดไอคอนส่วนขยายที่มุมขวาล่างของกลุ่ม "ตัวเลือกเพิ่มเติม"
• ถัดไป ในกล่องโต้ตอบ "คุณสมบัติ" ป๊อปอัพ คุณจะเห็นว่าอีเมลนี้ถูกกำหนดด้วยประเภทสีเดียวกันกับอีเมลต้นฉบับ

แก้ไขไฟล์ Outlook ที่เสียหาย

เนื่องจาก Outlook มีความเสี่ยง คุณต้องดำเนินการหลายอย่างเพื่อหลีกเลี่ยงการสูญหายของข้อมูล Outlook ตัวอย่างเช่น คุณต้องทำการสำรองข้อมูลเป็นระยะ นอกจากนี้ คุณจำเป็นต้องระวังอีเมลที่ไม่รู้จัก รวมถึงลิงก์หรือไฟล์แนบที่ฝังไว้ สุดท้าย แต่ไม่ท้ายสุด คุณควรได้รับเครื่องมือแก้ไขภายนอกระดับสุดยอด เช่น DataNumen Outlook Repair. สามารถช่วยให้คุณดึงข้อมูลสูงสุดจาก Outlook เสียหาย ไฟล์

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ SQL Server แก้ไขปัญหา และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.