3 วิธีในการรับสถิติจำนวนคำที่เกี่ยวข้องกับกล่องข้อความเชิงอรรถและอ้างอิงท้ายเรื่องในเอกสารของคุณ

ในบทความของวันนี้มี 3 วิธีอย่างรวดเร็วในการรับสถิติการนับจำนวนคำที่เกี่ยวข้องกับกล่องข้อความเชิงอรรถและอ้างอิงท้ายเรื่องในเอกสารของคุณ

การนับจำนวนคำทั้งหมดในเอกสารไม่ใช่เรื่องยาก แต่ถ้าคุณต้องการรับจำนวนคำของข้อความประเภทต่างๆจะต้องมีการดำเนินการเพิ่มเติม ต่อไปนี้เป็น 3 วิธี อ่านต่อเพื่อดูว่าคุณสามารถใช้อะไรได้บ้าง 

วิธีที่ 1: นับคำรวมทั้งข้อความจากกล่องข้อความเชิงอรรถและอ้างอิงท้ายเรื่อง

ตามค่าเริ่มต้น Word จะนับคำทั้งหมดที่ปรากฏบนเอกสารรวมถึงข้อความในกล่องข้อความและคำจากเชิงอรรถและอ้างอิงท้ายเรื่องด้วย

1. อันดับแรก ไปที่แถบสถานะแล้วคลิก "คำ" เพื่อเปิดกล่อง "จำนวนคำ"
2. คุณจะเห็นสถิติทุกประเภท ตรวจสอบให้แน่ใจว่าคุณได้เลือกช่อง "รวมกล่องข้อความเชิงอรรถและอ้างอิงท้ายเรื่อง"
3. จากนั้นคลิก“ ปิด”
4. หากคุณไม่พบคำสั่ง“ Words” บนแถบสถานะให้คลิกขวาที่นั่น
5. จากนั้นตรวจสอบ "จำนวนคำ"

วิธีที่ 2: ไม่รวมข้อความจากกล่องข้อความเชิงอรรถและอ้างอิงท้ายเรื่องจากจำนวนคำ

ซึ่งตรงข้ามกับวิธีที่ 1 ดังนั้นคุณเพียงแค่ต้องยกเลิกการเลือกช่อง "รวมกล่องข้อความเชิงอรรถและอ้างอิงท้ายเรื่อง"

วิธีที่ 3: เรียกใช้ Word Macro เพื่อแยกจำนวนคำออกจากกล่องข้อความเชิงอรรถและอ้างอิงท้ายเรื่อง

1. ประการแรกทริกเกอร์ช่อง "จำนวนคำ" โดยใช้วิธีที่ 1 และตรวจสอบให้แน่ใจว่าได้เลือกช่องตัวเลือกแล้ว
2. จากนั้นกด“ Alt + F11” เพื่อเปิดตัวแก้ไข VBA
3. จากนั้นแทรกโมดูลใหม่ในโปรเจ็กต์“ ปกติ” โดยคลิก“ ปกติ” ก่อน
4. แล้วคลิก "แทรก" ถัดไป
5. เลือก“ โมดูล” แล้ว
6. ดับเบิลคลิกที่โมดูลเพื่อเปิดพื้นที่การเข้ารหัสและวางรหัสต่อไปนี้:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. สุดท้ายคลิกปุ่ม“ Run”

หากไม่มีกล่องข้อความเชิงอรรถหรืออ้างอิงท้ายเรื่องคุณจะได้รับกล่องข้อความดังนี้:

เพียงคลิก“ ตกลง” เพื่อดำเนินการต่อ จากนั้นคุณจะเห็นอีกช่องหนึ่งซึ่งแสดงรายละเอียดทั้งหมดของการนับจำนวนคำ

รับเครื่องมือการกู้คืน

เนื่องจาก Word สามารถยุบได้ในทันทีขอแนะนำให้ซื้อผลิตภัณฑ์ซ่อมแซมขั้นสูงเพื่อทำงานแก้ไข เครื่องมือดังกล่าวสามารถช่วยประหยัดได้มากสำหรับ Word เสียหาย. ดังนั้นจงยึดเวลาให้ได้โดยเร็วที่สุด

บทนำผู้เขียน:

Vera Chen เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ แก้ไข xls และ pdf ซ่อมแซมผลิตภัณฑ์ซอฟต์แวร์ ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.