3 วิธีมาโครในการแปลงเอกสาร Word ของคุณอย่างรวดเร็ว PDF ไฟล์

ในบทความนี้ เราจะเน้นให้คุณมีมาโคร 3 ตัว ซึ่งคุณสามารถใช้เพื่อแปลงเอกสาร Word ได้อย่างรวดเร็ว pdf ไฟล์

ใน Word 2003 จะมีไอคอนอยู่บนแถบเมนู ด้วยการคลิกเพียงครั้งเดียว ผู้ใช้สามารถเรียกใช้หน้าต่าง "บันทึกเป็น" ได้ทันทีและบันทึกเอกสารลงไป pdf จัดรูปแบบ

อย่างไรก็ตาม อย่างที่คุณสังเกตเห็น เค้าโครงใน Word 2010 เปลี่ยนแปลงไปมาก และผู้ใช้ต้องคลิกแท็บ "ไฟล์" จากนั้นคลิกคำสั่ง "บันทึกเป็น" เพื่อเรียกหน้าต่าง "บันทึกเป็น" นอกจากนี้ คุณต้องเลือกประเภทการบันทึกด้วยตนเองก่อนที่จะกดปุ่ม "บันทึก"

ด้วยการคลิกหลายครั้งเช่นนี้ มันจึงยังไม่เร็วพอ ดังนั้น ในบทความนี้ เราจึงอยากจะแสดงวิธีการแบบมาโครในการทำเช่นนั้น

มาโคร 1: เรียกใช้หน้าต่าง "บันทึกเป็น" อย่างรวดเร็ว

1. อันดับแรก ให้คลิกแท็บ “นักพัฒนา” จากนั้นคลิกคำสั่ง “Visual Basic” เพื่อเปิดตัวแก้ไข VBA แน่นอนว่าต้องคลิกสองครั้งนี้เมื่อแท็บ “นักพัฒนา” แสดงอยู่แล้ว อีกวิธีหนึ่งคือการกด “Alt+F11”
2. ประการที่สองคลิกโครงการ "ปกติ"
3. ประการที่สาม คลิก "แทรก" จากนั้นเลือก "โมดูล" บนเมนูรายการ
4. ตอนนี้ดับเบิลคลิกที่โมดูลเพื่อแสดงพื้นที่แก้ไข
5. จากนั้นวางรหัสต่อไปนี้:

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

6. จากนั้นคลิก "เรียกใช้"

ตอนนี้หน้าต่าง “บันทึกเป็น” ปรากฏขึ้นแล้ว และประเภทการบันทึกก็ถูกตั้งค่าเป็น PDF เรียบร้อยแล้ว สิ่งที่คุณต้องทำก็คือคลิกปุ่ม “บันทึก” มาโครนี้ช่วยให้คุณสามารถเปลี่ยนชื่อไฟล์ได้หากจำเป็น

มาโคร 2: บันทึกไฟล์ Word เป็น PDF โดยตรง

ในกรณีที่มีบางคนต้องการบันทึกไฟล์โดยตรงไปที่ pdf โดยไม่ต้องแก้ไขชื่อไฟล์ นี่คือมาโครที่ต้องการ

1. ก่อนอื่น ทำซ้ำ 4 ขั้นตอนแรกข้างต้น
2. ถัดไป วางรหัสต่อไปนี้แทน:

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

3. ในทำนองเดียวกันคลิก "เรียกใช้"

มาโคร 3: แปลงไฟล์ Word Docx เป็น PDF จำนวนมาก

1. วางไฟล์ docx ทั้งหมดไว้ในโฟลเดอร์เดียวก่อน
2. ทำตามขั้นตอนข้างต้นเพื่อเปิดพื้นที่แก้ไข
3. จากนั้นวางมาโครด้านล่าง:

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. อย่าลืมคลิกปุ่ม "เรียกใช้"

หมายเหตุ: ในรหัส “strFolder = “C:\Users\Test\Desktop\Test Files\””,““C:\Users\Test\Desktop\Test Files\”” คือเส้นทางไฟล์ของโฟลเดอร์ อย่าลืมเปลี่ยนให้เหมาะสม

หลังจากเรียกใช้มาโครนี้แล้ว ไฟล์ PDF จะถูกบันทึกไว้ในโฟลเดอร์เดียวกับที่เอกสาร Word อยู่

รักษาความปลอดภัยไฟล์เท่าที่จะทำได้

มีมาตรการป้องกันและขั้นตอนหลังเกิดภัยพิบัติเพื่อกู้คืนไฟล์ที่เสียหาย หากคุณสำรองข้อมูลไฟล์ของคุณเป็นประจำ การกู้คืนไฟล์ต้นฉบับก็ไม่ใช่เรื่องยาก แต่ความจริงก็คือ คนส่วนใหญ่ไม่สามารถปฏิบัติตามแผนการสำรองข้อมูลได้ ทำให้มีความเสี่ยงสูงที่จะสูญเสียข้อมูลสำคัญ ในสถานการณ์เช่นนี้ ถึงเวลาแล้วที่จะต้องหันมาใช้ระบบสำรองข้อมูลขั้นสูง เครื่องมือแก้ไขความเสียหายของเอกสาร Word.

บทนำผู้เขียน:

Vera Chen เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ แก้ไข Excel xlsx ที่เสียหาย และ pdf ซ่อมแซมผลิตภัณฑ์ซอฟต์แวร์ ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.