2 วิธีด่วนในการค้นหาหรือลบประโยคที่มีข้อความเฉพาะใน Word ของคุณ

ในบทความนี้ เราจะเสนอ 2 วิธีที่รวดเร็วในการค้นหาหรือลบประโยคที่มีข้อความเฉพาะใน Word ของคุณ

เป็นที่ทราบกันดีอยู่แล้วว่าเราสามารถใช้ฟังก์ชัน “ค้นหาและแทนที่” ใน Word เพื่อค้นหาคำที่ต้องการได้อย่างง่ายดาย จากนั้นเราก็จะสามารถไฮไลต์ แทนที่ หรือลบคำเหล่านั้นได้โดยไม่มีปัญหา อย่างที่คุณเห็น เป้าหมายคือคำหรือวลี อย่างไรก็ตาม วันนี้เรามีความยินดีที่จะบอกคุณถึงวิธีการใช้มาโครในการค้นหาหรือลบประโยคที่มีข้อความที่ต้องการ

วิธีที่ 1: ค้นหาหรือลบประโยคที่มีข้อความเฉพาะ

1. เริ่มต้นด้วยการกด“ Alt + F11” เพื่อทริกเกอร์ตัวแก้ไข VBA ใน Word
2. จากนั้นสร้างโมดูลใหม่โดยคลิก "ปกติ"
3. จากนั้นคลิก "แทรก" และเลือก "โมดูล" เพื่อรับอันใหม่
4. และเปิดโมดูลด้วยการดับเบิลคลิก
5. ตอนนี้วางรหัสต่อไปนี้:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. จากนั้นคลิก“ Run”
7. จะมีช่องใส่ข้อความให้ใส่ข้อความ เพียงพิมพ์ข้อความทั่วไปที่มีทุกประโยค คลิก "ตกลง"
8. จากนั้นคุณจะเห็นประโยคที่มีข้อความที่เลือกพร้อมกล่องข้อความปรากฏขึ้น คลิก "ใช่" เพื่อลบประโยค และ "ไม่ใช่" เพื่อเก็บไว้
9. หลังจากยืนยันแล้ว ประโยคถัดไปที่มีข้อความที่กำหนดไว้จะถูกเลือก และจะมีกล่องยืนยันปรากฏขึ้นด้วย กล่าวคือ มาโครจะนำคุณไปทีละขั้นตอนทั่วทั้งเอกสาร ค้นหาประโยคเป้าหมาย และขอการยืนยันจากคุณทุกครั้ง

วิธีที่ 2: ค้นหาหรือลบประโยคที่มีข้อความใด ๆ ในรายการ

ด้วยมาโครในวิธีที่ 1 คุณสามารถค้นหาได้ครั้งละหนึ่งคำหรือวลีเท่านั้น แน่นอน คุณสามารถเรียกใช้แมโครซ้ำๆ เพื่อค้นหาคำหรือวลีหลายอินสแตนซ์ เพื่อตอบสนองความต้องการในการค้นหาหลายรายการ เราจะจัดเตรียมมาโครอีกอันให้กับคุณ

1. ขั้นแรก ให้คัดลอกข้อความเป้าหมายทั้งหมดลงในเอกสารใหม่ ตรวจสอบให้แน่ใจว่าข้อความแต่ละส่วนอยู่ในย่อหน้าเดียวโดยไม่มีช่องว่างท้ายข้อความ ปิดและบันทึกเอกสาร
2. ถัดไปติดตั้งและเรียกใช้แมโครตามขั้นตอนที่แน่นอนในวิธีที่ 1
3. จากนั้นแทนที่มาโครด้วยอันนี้:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. ตอนนี้หน้าต่าง "เรียกดู" จะเปิดขึ้น เลือกเอกสารที่เพิ่งบันทึกแล้วคลิก "เปิด"
5. ขั้นตอนต่อไปนี้จะเหมือนกับในวิธีที่ 1

แนวทางการจัดการกับเอกสารทุจริต

การสูญเสียข้อมูลอันมีค่าถือเป็นหายนะอย่างยิ่ง มันอาจทำให้ธุรกิจของคุณตกอยู่ในความเสี่ยงได้ เพื่อหลีกเลี่ยงความยุ่งยากดังกล่าว คุณต้องได้รับ a แก้ไข Word เครื่องมือโดยเร็วที่สุด เครื่องมือดังกล่าวจะช่วยให้คุณชนะการต่อสู้กับการทุจริตของเอกสาร

บทนำผู้เขียน:

Vera Chen เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ แก้ไข Excel และ pdf ซ่อมแซมผลิตภัณฑ์ซอฟต์แวร์ ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.