2 วิธีด่วนในการส่งออกรายการอีเมล Outlook ที่ถูกตั้งค่าสถานะทั้งหมดไปยัง Excel

หากคุณต้องการส่งออกรายการอีเมลที่ติดธงทำเครื่องหมายทั้งหมดจากกล่องจดหมาย Outlook ของคุณไปยัง Excel คุณสามารถใช้วิธีใดวิธีหนึ่งจาก 2 วิธีที่แชร์ในบทความนี้

ตัวอย่างเช่นเพื่อจัดการกับอีเมลที่ถูกตั้งค่าสถานะทั้งหมดได้ทันท่วงทีมากขึ้นหรือแบ่งปันกับคนอื่นคุณอาจต้องการส่งออกไปยังแผ่นงาน Excel ในที่นี้เราจะแนะนำ 2 แนวทางที่ควรตระหนัก ก่อนหน้านี้ใช้คุณลักษณะ "นำเข้าและส่งออก" มาตรฐานหลังจากพบอีเมลที่ถูกตั้งค่าสถานะ บอกตามตรงว่ามันค่อนข้างน่าเบื่อ ดังนั้นในตอนหลังเราจะสอนวิธีที่สะดวกกว่าในการใช้ VBA

วิธีที่ 1: ส่งออกอีเมลที่ถูกตั้งค่าสถานะทั้งหมดด้วยตนเอง

1. ก่อนอื่นให้คลิกในช่องค้นหาเหนือรายชื่อเมล
2. จากนั้นคลิก "รายการเมลทั้งหมด" ในกลุ่ม "ขอบเขต" บนแท็บ "ค้นหา"
3. จากนั้นคลิกปุ่ม "ตั้งค่าสถานะ" ในกลุ่ม "กำหนด"
4. หลังจากอีเมลที่ติดธงทำเครื่องหมายทั้งหมดที่แสดงในรายการให้เลือกหนึ่งอีเมลแล้วกด“ Ctrl + A” เพื่อเลือกทั้งหมด
5. จากนั้นกดแป้นลัด“ Ctrl + Shift + V”
6. ในกล่องโต้ตอบใหม่ให้สร้างโฟลเดอร์ใหม่ภายใต้ไฟล์ Outlook
7. จากนั้นเลือกโฟลเดอร์ที่สร้างขึ้นใหม่แล้วคลิก“ ตกลง” ซึ่งจะย้ายอีเมลที่ถูกตั้งค่าสถานะทั้งหมดไปยังโฟลเดอร์ใหม่
8. หลังจากนั้นคลิก“ ไฟล์”>“ เปิด”>“ นำเข้า”
9. ในกล่องโต้ตอบป๊อปอัปให้เลือก“ ส่งออกเป็นไฟล์”>“ ถัดไป”>“ Microsoft Excel 97-2003”>“ ถัดไป”
10. ในหน้าจอใหม่ให้เลือกโฟลเดอร์ที่ถูกต้องแล้วกด“ ถัดไป”
11. จากนั้นทำตามวิซาร์ดเพื่อดำเนินการ“ ส่งออก” ให้เสร็จสมบูรณ์
12. คุณจะได้ไฟล์ Excel ใหม่ดังภาพหน้าจอต่อไปนี้

วิธีที่ 2: ส่งออกรายการอีเมลที่ถูกตั้งค่าสถานะทั้งหมดผ่าน VBA

1. ใน Outlook ให้กด“ Alt + F11” เพื่อทริกเกอร์ตัวแก้ไข VBA
2. จากนั้นเปิดใช้งาน“ MS Excel Object” ตาม“วิธีเพิ่ม Object Library การอ้างอิงใน VBA"
3. จากนั้นคัดลอกโค้ด VBA ด้านล่างลงในโมดูล

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. สุดท้ายวางเคอร์เซอร์ไว้ในรูทีนย่อย“ ExportAllFlaggedEmailsToExcel” แล้วกดปุ่ม“ F5”
5. จากนั้นเลือกไฟล์ Outlook ในกล่องโต้ตอบใหม่
6. เมื่อคุณได้รับข้อความแจ้งว่า "เสร็จสมบูรณ์" คุณจะได้รับไฟล์ Excel ใหม่ดังภาพด้านล่าง

ปกป้อง Outlook ของคุณจากความเสียหาย

Outlook มีแนวโน้มที่จะเกิดข้อผิดพลาดและความเสียหายดังนั้นจึงเป็นงานที่ยากมากสำหรับเราในการปกป้องข้อมูล Outlook ของเรา ไม่ต้องสงสัยมost วิธีที่ได้ผลและใช้งานได้จริงคือการสำรองข้อมูลสำหรับ Outlook เป็นประจำ นอกจากนี้ยังจำเป็นที่เราจะต้องได้รับเครื่องมือแก้ไข Outlook ที่มีประสิทธิภาพและน่าเชื่อถือเช่น DataNumen Outlook Repair. มันจะมีประโยชน์ถ้า เครื่องมือซ่อมแซมกล่องจดหมาย ทำให้ไม่มีผล

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ แก้ไขปัญหา SQL Server และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.