2 วิธีที่รวดเร็วในการแยกส่วนจากเอกสาร Word ของคุณ

ในบทความนี้เราจะเสนอ 2 วิธีที่ง่ายและรวดเร็วในการแยกส่วนจากเอกสาร Word ของคุณไปยังอีกส่วนหนึ่ง

เกิดขึ้นบ่อยครั้งในการแยกเนื้อหาจากเอกสารหนึ่งไปยังอีกเอกสารหนึ่ง และในบทความก่อนหน้านี้เราได้กล่าวถึงวิธีการแยกหน้าจากเอกสาร สำหรับข้อมูลโดยละเอียดคุณสามารถอ้างถึงบทความนี้: 2 วิธีด่วนในการแยกแต่ละหน้าออกจากเอกสาร Word ของคุณ

วันนี้เราจะแสดงวิธีการแยกตามส่วน    

วิธีที่ 1: แยกส่วนปัจจุบันไปยังเอกสารใหม่

1. ขั้นแรก ให้วางเคอร์เซอร์ไว้ในส่วนเป้าหมาย
2. จากนั้นกด“ Alt + F11” เพื่อเรียกใช้โปรแกรมแก้ไข VBA ใน Word
3. จากนั้นในคอลัมน์ทางซ้ายคลิกที่“ ปกติ”
4. และบนแถบเมนูคลิก "แทรก"
5. จากนั้นเลือก "โมดูล" ในเมนูแบบเลื่อนลงนั้น
6. ดับเบิลคลิกเพื่อเปิดโมดูลใหม่และวางรหัสต่อไปนี้:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. จากนั้นคลิก“ Run” บนแถบเมนูหรือกด“ F5”
8. จากนั้นจะมีหน้าต่าง "เรียกดู" ปรากฏขึ้น เลือกสถานที่จัดเก็บเอกสารใหม่แล้วคลิก“ ตกลง”
9. และในช่อง“ ชื่อไฟล์” ให้ป้อนชื่อไฟล์ใหม่แล้วคลิก“ ตกลง”

ตอนนี้คุณได้แยกส่วนนี้ไปยังเอกสารใหม่

วิธีที่ 2: แยกแต่ละส่วนในเอกสารไปยังคนใหม่แต่ละคน

วิธีนี้จะช่วยให้คุณประมวลผลส่วนทั้งหมดในเอกสารเป็นกลุ่มได้ แน่นอนว่าเราจะต้องมีมาโครด้วย

1. ขั้นแรก ให้เปิดเอกสารเป้าหมาย
2. จากนั้นทำตามขั้นตอนในวิธีที่ 1 เพื่อติดตั้งและเรียกใช้แมโคร
3. คราวนี้แทนที่มาโครนั้นด้วยมาโครนี้เท่านั้น:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. ถึงกระนั้นในหน้าต่าง“ เรียกดู” ให้เลือกเส้นทางการจัดเก็บและคลิก“ ตกลง”

แก้ไขข้อผิดพลาดของ Word ที่ทำให้ระคายเคือง

เป็นเรื่องปกติที่จะพบข้อผิดพลาดของ Word ขณะใช้งาน อาจเป็นเรื่องที่น่ารำคาญเราต้องใช้เวลา กู้คืนคำ โดยเร็วที่สุด เนื่องจากยิ่งเราล่าช้านานเท่าไหร่ข้อมูลก็จะยิ่งสูญหายอย่างรุนแรง ดังนั้นจึงขอแนะนำให้เก็บเครื่องมือซ่อมแซมไว้ล่วงหน้า

บทนำผู้เขียน:

Vera Chen เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ xls ที่เสียหาย และ pdf ซ่อมแซมผลิตภัณฑ์ซอฟต์แวร์ ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.