Kako hitro združiti in izvoziti več prilog Excelovega delovnega zvezka v en delovni zvezek v Outlooku

Skupna raba zdaj:

Ko prejmete e-poštno sporočilo z več Excelovimi delovnimi zvezki, če želite preveriti vsebino vseh delovnih zvezkov v enem delovnem zvezku, lahko uporabite način v tem članku. Izvozil bo več prilog Excelovega delovnega zvezka v en delovni zvezek.

Če si želite ogledati vse priloge e-poštnega sporočila v enem Excelovem delovnem zvezku, morate najprej združiti in izvoziti te priloge v en sam delovni zvezek. Namesto da to storite ročno, lahko za to preprosto uporabite naslednjo metodo. Naučila vas bo uporabljati kodo VBA za to. Glede uporabe VBA si lahko ogledate objavo "Kako zagnati kodo VBA v Outlooku".

Hitro združite in izvozite več prilog Excelovega delovnega zvezka v en delovni zvezek v Outlooku

Združite in izvozite več prilog Excelovega delovnega zvezka v en delovni zvezek

  1. Za začetek zaženite aplikacijo Outlook.
  2. Nato odprite urejevalnik Outlook VBA.
  3. Nato morate v novem oknu »Microsoft Visual Basic for Applications« omogočiti »Knjižnico objektov MS Excel«, o čemer si lahko preberete v članku – »Kako dodati referenco knjižnice objektov v VBA".
  4. Nato kopirajte naslednjo kodo VBA v projekt ali modul.
Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

Koda VBA - Združite in izvozite več prilog Excelovega delovnega zvezka v en delovni zvezek

  1. Po tem lahko zaprete okno in dodate nov makro v orodno vrstico za hitri dostop.
  2. Pozneje se obrnite na izvorno e-pošto na poštnem seznamu.
  3. Nato pridržite »Ctrl«, da izberete priloge Excelovega delovnega zvezka, ki jih želite izvoziti.
  4. Nato kliknite gumb makra v orodni vrstici za hitri dostop.Gumb Zaženi makro v orodni vrstici za hitri dostop
  5. Ko se makro zaključi, se prikaže nov Excelov delovni zvezek. Vsebovala bo vsebino predhodno izbranih Excelovih delovnih zvezkov.Izvožen Excelov delovni zvezek

Uporabite močnejše zunanje orodje za popravilo

Pri srečanju s korupcijo v Outlooku bo večina uporabnikov uporabila orodje za popravilo nabiralnika najprej poskusiti. Vendar pa to ne bo veliko pomagalo v primeru resne poškodbe. Takrat vam ne preostane drugega, kot da si pomagate z zunanjim zanesljivim in izkušenim orodjem, kot je npr DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z izterjava mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com

Skupna raba zdaj:

Komentarji so zaprti.