Kako hitro priložiti določene diapozitive a PowerPoint Predstavitev v vašo Outlookovo e-pošto

Če želite izvleči določene diapozitive a PowerPoint predstavitve v ločeno novo predstavitev in jo priložite Outlookovemu e-poštnemu sporočilu, lahko uporabite način, ki je prikazan v tem članku.

Namesto da bi priložil celotno PowerPoint predstavitev v e-pošto, če želite priložiti določene diapozitive predstavitve, morate na splošno najprej kopirati določene diapozitive v novo predstavitev. Preveč je težavno. Zato vam bomo tukaj pokazali metodo, s katero lahko to uresničite naenkrat.

Priložite posebne diapozitive a PowerPoint Predstavitev na e-pošto

1. Najprej odprite posebno PowerPoint predstavitev.
2. Nato v PowerPoint okno aplikacije pritisnite tipki “Alt + F11” za dostop do urejevalnika VBA.
3. Nato v novem oknu ustvarite nov modul tako, da kliknete »Vstavi« > »Modul«.
4. Nato v ta modul kopirajte in prilepite naslednjo kodo VBA.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Po tem lahko zaprete trenutno okno.
6. Pozneje pojdite na »Datoteka« > »Možnosti« > »Orodna vrstica za hitri dostop«, da dodate nov makro v orodno vrstico za hitri dostop.
7. Končno lahko preizkusite ta makro.

• Kajti kottart izberite določene diapozitive, ki jih želite ekstrahirati.
• Nato v orodni vrstici za hitri dostop kliknite gumb makra.
• Takoj se prikaže Outlookovo e-poštno sporočilo, v katerem je PowerPoint predstavitev, ki je izvlečena iz izvorne predstavitve.

Uporabite učinkovito orodje za obnovitev

Kot vsi vemo, je Outlook opremljen z vgrajenim pripomočkom za popravilo – scanpst. Vendar pa se lahko preprosto spopade z majhnimi napakami v Outlooku. Če je to, s čimer ste soočeni, resna škoda, ne bo imela učinka. Takrat vam ne preostane drugega, kot da se vrnete k drugemu zmogljivemu in zanesljivemu orodju za popravilo, kot je DataNumen Outlook Repair. Z njim boste lahko rešili svojo poškodovano datoteko Outlook.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z poškodovan mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com