Kako hitro izvoziti statistiko glasovanja iz Outlookovega e-poštnega sporočila v Excelov delovni list

Če ste poslali e-poštno sporočilo z gumbi za glasovanje, potem ko vam prejemniki pošljejo svoje odgovore, boste morda želeli prešteti in izvoziti statistiko glasovanja v Excelov delovni list. Torej, v tej strost, naučili vas bomo, kako to hitro doseči.

Outlook je tako zmogljiv, da ponuja celo funkcijo »Glasovanje«. Moj prejšnji članek "Spretna uporaba MS Outlook za glasovanje” je naučil, kako ga učinkovito uporabljati. Tudi most časa, lahko po glasovanju nadaljujete z izvozom statistike glasovanja v Excelov delovni list iz nekaterih razlogov, na primer, če želite natisniti statistiko. Toda Outlook tega privzeto ne podpira. Tako vas bomo v nadaljevanju naučili, kako to realizirati kot zamašek.

Izvozite statistiko glasovanja v e-pošti v Excelov delovni list

1. Na začetku zaženite aplikacijo Outlook.
2. Nato bi morali v glavnem oknu programa Outlook pritisniti tipke »Alt + F11«.
3. Nato v oknu »Microsoft Visual Basic za aplikacije« omogočite »Microsoft Excel Object Library«. Kliknite »Orodja« > »Referenca«. Nato v pojavnem pogovornem oknu označite potrditveno polje pred »Microsoft Excel Object Library« in nazadnje pritisnite »V redu«.
4. Po tem lahko vstavite nov modul ali odprete tistega, ki ni v uporabi.
5. Nato v ta modul kopirajte in prilepite naslednje kode VBA.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Po tem, za priročen dostop, je bolje, da nov makro dodate v orodno vrstico za hitri dostop.
6. Sčasoma lahko poskusite.

• Najprej izberite izvorno e-pošto, ki vsebuje gumbe za glasovanje.
• Nato v orodni vrstici za hitri dostop kliknite gumb makra.
• Ko se ta makro zažene, lahko pobrskate do vnaprej določene lokalne mape, v kateri boste videli nov Excelov delovni zvezek.
• Odprite ta Excelov delovni zvezek. Zdaj boste videli statistiko glasovanja, prikazano na spodnji sliki:

Nihče ne more temeljito preprečiti Outlookovih napak

Čeprav je Outlook opremljen z različnimi zmožnostmi, ni takšne funkcije, ki bi nam pomagala preprečiti napake Outlooka. Vse vrste dejavnikov lahko povzročijo napake Outlooka. Na primer, če pogosto nepravilno zaprete Outlook, boste verjetno trpeli PST korupcija. V takem primeru vam ne preostane drugega, kot da uporabite nekatera zmogljiva orodja za reševanje vaše datoteke PST, npr. DataNumen Outlook Repair. Zaradi visoke stopnje okrevanja si je prislužil veliko pohval.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z pokvarjen mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com