Kako hitro izvoziti skupni čas, porabljen za Outlookove sestanke v vsaki barvni kategoriji

Če želite ustvariti poročilo o skupnem času, ki ga porabite za sestanke v vsaki barvni kategoriji, lahko uporabite metodo, predstavljeno v tem članku. To vam lahko pomaga hitro doseči, ne da bi morali ročno šteti.

Mnogi uporabniki so vajeni beležiti večino svojih dejavnosti v Outlookovem koledarju. Da bi jih lažje upravljali in razlikovali, jim dodelijo kategorije. V tem primeru bi nekateri uporabniki radi ustvarili poročilo, ki prikazuje skupni čas, porabljen za elemente koledarja v vsaki barvni kategoriji. Nedvomno je štetje in ročni vnos težavno. Zato bomo tukaj delili način, kako to nalogo opraviti s preprostim klikom.

Izvoz skupnega časa, porabljenega za sestanke v vsaki barvni kategoriji

1. Najprej zaženite aplikacijo Outlook.
2. Potem, ko vstopite v Outlookovo okno, se lahko dotaknete tipk »Alt + F11«.
3. Nato boste dobili dostop do okna »Microsoft Visual Basic for Applications«.
4. Nato boste morali omogočiti »Knjižnico predmetov Microsoft Excel«. To storite tako, da kliknete »Orodja« > »Referenca«.
5. Nato bi morali najti in odpreti modul, ki ni v uporabi.
6. Po tem morate v ta modul kopirati naslednjo kodo VBA.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Končno lahko sprožite ta makro, ne glede na to, da kliknete ikono »Zaženi« v orodni vrstici ali pritisnete tipko »F5«.
8. Nato boste morali izbrati določen koledar.
9. Ko izberete in pritisnete »V redu«, se bo makro še naprej izvajal. Ko se konča, bo v ozadju prikazana nova Excelova datoteka.
10. Do njega lahko dostopate. Videti bo kot naslednji posnetek zaslona:

Bodite pozorni na morebitne grožnje okoli vašega Outlooka

Uporabniki Outlooka morajo biti pozorni na vsa možna tveganja, vključno z neznanimi e-poštnimi prilogami, vdelanimi povezavami in človeškimi napakami. V nasprotnem primeru se lahko vaš Outlook kadar koli poškoduje. Prav tako sta nujna izdelava rednih varnostnih kopij Outlookovih podatkov in vzdrževanje specializiranega orodja za popravilo. DataNumen Outlook Repair je eno najbolj priporočljivih orodij za popravila. Lahko popravilo Outlook težave v hipu.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z poškodovan mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com