Kako hitro izvoziti vse slikovne priloge Outlookove e-pošte v Excelov delovni list

Če želite hitro izvoziti vse slikovne priloge Outlookove e-pošte v Excelov delovni list, si oglejte ta članek. Tukaj vam bomo pokazali učinkovitejši način od ročnega izvažanja.

Ko prejmete e-pošto, ki vsebuje številne slikovne priloge in jih želite uporabiti za izdelavo poročila v Excelu, morate najti način, s katerim lahko te slike v paketih izvozite v Excelov delovni list. V nadaljevanju vam bomo predstavili takšen pristop.

Izvozite vse slikovne priloge e-pošte v Excelov delovni list

1. Za začetek dostopajte do Outlookove aplikacije na običajen način.
2. Nato v Outlookovem oknu pritisnite bližnjične tipke »Alt + F11«, kar bo prikazalo okno »Microsoft Visual Basic za aplikacije«.
3. Na tem zaslonu morate odpreti modul, ki ga ne uporabljate, ali neposredno vstaviti novega.
4. Nato bi morali v ta modul kopirati spodnji del kode VBA.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Po tem lahko zapustite makro.
6. Nato pojdite na »Datoteka« > »Možnosti« > »Orodna vrstica za hitri dostop«, da dodate ta makro v orodno vrstico za hitri dostop.
7. Končno lahko poskusite ta makro zdaj.

• Najprej izberite ali odprite izvorno e-pošto.
• Nato v orodni vrstici za hitri dostop kliknite gumb makra.
• Ko je makro dokončan, boste dobili Excelov delovni list, prikazan kot ta posnetek zaslona:

Zaščitite Outlookovo datoteko pred poškodbami

Znano je, da je Outlook nagnjen h korupciji. Zato bi morali razumeti, kako zaščititi Outlookov obrazec pred poškodbami. Najprej, da bi preprečili virusne napade, je treba namestiti protivirusno programsko opremo in nikoli ne prenašati neznane priloge. Poleg tega je bolje, da se dokopamo do močnega orodja za popravilo, kot je npr DataNumen Outlook RepairPonuja lahko najučinkovitejše zdravilo v primeru Outlook korupcija.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z obnovitev sql in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com