Kako prikazati ustrezne starosti oseb za vse rojstnodnevne dogodke v pogledu seznama Outlookovega koledarja

Nekateri uporabniki bi radi videli tudi starost ustrezne osebe, ko si ogledujejo rojstni dan v koledarju. Zato bomo v tem članku delili metodo za enostavno uresničitev te zamisli.

Ko dodate informacije o rojstnem dnevu stiku, bo Outlook samodejno ustvaril rojstni dan v koledarju. V teh okoliščinah boste morda želeli pridobiti tudi starost ustreznih oseb vsakič, ko vidite rojstnodnevne dogodke v koledarju. Zato vam bomo tukaj predstavili način, kako to uresničiti.

Prikažite ustrezne starosti oseb za vse rojstnodnevne dogodke v pogledu seznama

1. Na samem začetku zaženite urejevalnik Outlook VBA.
2. Nato v modul kopirajte naslednjo kodo.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. Po tem postavite kazalec v prvi podprogram in pritisnite "F5", da zaženete ta makro.
4. Ko se makro konča, zapustite urejevalnik VBA in odprite mapo koledarja.
5. Nato pojdite na zavihek »Pogled« in kliknite »Spremeni pogled« > »Seznam«.
6. Nato kliknite gumb »Ogled nastavitev«.
7. V pojavnem pogovornem oknu izberite »Stolpci«.
8. Nato v naslednjem pogovornem oknu »Prikaži stolpce« s seznama »Izberi razpoložljiva polja iz« izberite »Uporabniško določena polja v mapi«.
9. Kasneje se obrnite na »Starost« v polju »Razpoložljivi stolpci« in kliknite gumb »Dodaj ->«.
10. Sčasoma kliknite vrsto »V redu«, dokler se ne vrnete na seznam elementov koledarja.
11. Zdaj lahko na seznamu vidite starost oseb za vse rojstnodnevne dogodke, kot je prikazano na naslednji sliki.

Popravite ogroženo Outlook datoteko

Ob srečanju vas lahko zagrabi panika pokvarjen Outlook ki vsebuje veliko vaših dragocenih e-poštnih sporočil in urnikov. Ne glede na to, da je taka težava precej obupna, se morate vseeno takoj umiriti in razmisliti o učinkovitih ukrepih. Če ste še naprej zaskrbljeni, se lahko stanje poslabša in poslabša. Pravzaprav obstaja več načinov in pripomočkov, s katerimi lahko popravite poškodovano datoteko, na primer orodje za popravilo mape »Prejeto« in bolj robustno in izkušeno orodje, kot je DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z SQL Server fiksna in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com