Kako hitro ustvariti skupino stikov iz vseh Outlookovih stikov z določenim naslovom delovnega mesta

Da boste lažje komunicirali s stiki z določenim naslovom dela, boste morda želeli hitro ustvariti skupino stikov iz teh stikov. V tem članku bomo z vami delili hitro metodo.

Če pogosto pošiljate e-poštna sporočila, opravila ali povabila na sestanke stikom z določenim naslovom dela, bo veliko bolj priročno, če iz njih ustvarite skupino stikov. Na splošno morate na standardni način najprej ustvariti novo skupino stikov in nato skupini dodati člane kot enega za drugim. To je nekoliko težavno. Zato vas bomo v nadaljevanju naučili veliko hitrejšega načina, kako to doseči.

Iz vseh stikov ustvarite skupino stikov z določenim naslovom delovnega mesta

1. Najprej v mapi Stiki izberite stik z določenim naslovom delovnega mesta.
2. Nato pritisnite “Alt + F11” za dostop do urejevalnika Outlook VBA.
3. Nato kopirajte naslednjo kodo VBA v prazen modul ali projekt.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Po tem premaknite kazalec v prvo podprogram.
5. Na koncu pritisnite tipko “F5”, da zaženete ta makro.
6. Ko se makro konča, se prikaže nova skupina stikov. Vsebuje vse stike z istim naslovom delovnega mesta izbranega stika v 1. koraku.

Učinkovito zaščitite podatke Outlook

Čeprav je Outlook bogat s funkcijami, se ne more znebiti dejstva, da je ranljiv. Če torej ne želite izgubiti dragocenih Outlookovih podatkov, se morate potruditi, da jih zaščitite. Na primer, v rednih časovnih presledkih morate varnostno kopirati podatke iz Outlooka. Če je cenovno ugodno, je priporočljivo imeti vrhunsko orodje za popravilo PST, kot je DataNumen Outlook Repair, ki lahko popravilo PST podatki v trenutku.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z poškodovan sql in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com