Kako samodejno nastaviti drugačen čas opomnika za Outlookove sestanke v različnih barvnih kategorijah

Če Outlookove sestanke razvrščate po barvnih kategorijah in želite nastaviti različen čas opomnika za sestanke v različnih barvnih kategorijah, si oglejte ta članek. Tukaj vas bomo naučili, kako to realizirati z Outlookom VBA.

Na primer, sestanke delite v dve skupini. Ena je v barvni kategoriji »Zunaj lokacije«, ker je lokacija sestanka predaleč, druga pa v barvni kategoriji »Na lokaciji«, ker je lokacija tukaj. Zdaj želite, da Outlook samodejno nastavi čas opomnika za sestanek »zunaj lokacije« na 1 uro pred začetkom in za sestanek »na lokaciji« na 15 minut pred začetkom. Glede na to zahtevo bomo v nadaljevanju delili hitro metodo.

Samodejna nastavitev različnih opomnikov za sestanke v različnih barvnih kategorijah

1. Za začetek zaženite aplikacijo Outlook.
2. Nato pritisnite tipke »Alt + F11« za dostop do okna urejevalnika VBA.
3. Nato v naslednjem oknu kopirajte in prilepite spodnjo kodo VBA v projekt »ThisOutlookSession«.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Kasneje morate klikniti na podprogram »Application_Startup« in pritisniti tipko »F5«, da zaženete ta makro.
5. Od takrat bo Outlook vsakič, ko je nov sestanek dodan v privzeti koledar ali ko spremenite obstoječe sestanek, samodejno preveril kategorije sestanka in samodejno nastavil drug čas opomnika.

Odpravite napake v Outlooku

Občasno se lahko v Outlooku pojavijo različne težave. Zato je izjemno pomembno, da se uporabniki naučijo, kako se spopasti s težavami v Outlooku. Za začetek je bolje, da redno varnostno kopirate podatke v Outlooku. Poleg tega je priporočljivo, da imate zmogljivo varnostno kopijo, če je to mogoče. Outlook popravilo orodje v bližini, na primer DataNumen Outlook Repair. Lahko skenira vašo datoteko PST, da ugotovi težave z Outlookom in jih nato z lahkoto reši.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z obnovitev sql in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com