Kako samodejno izvoziti informacije o dohodni e-pošti v Excelovo datoteko z Outlookom VBA

Mnogi uporabniki upajo, da lahko Outlook samodejno izvozi primarne informacije dohodnih e-poštnih sporočil v Excelovo datoteko. Ta članek bo obravnaval to zahtevo in predstavil hitro metodo prek Outlooka VBA.

Včasih boste zaradi nekaterih razlogov, kot je statistika pošte, morda pogosto morali izvoziti e-pošto v datoteko Excel. Na splošno lahko za obstoječa prejeta e-poštna sporočila preprosto uporabite funkcijo »Uvoz in izvoz«, da jih naenkrat izvozite v Excel. Morda pa si celo želite, da lahko Outlook samodejno izvozi dohodna e-poštna sporočila v Excel takoj, ko prispejo v vaš nabiralnik. Brez dvoma v Outlooku ni takšne izvorne funkcije. Zato morate uporabiti druge pristope, kot je dodatek tretje osebe ali Outlook VBA. Tukaj vas bomo naučili, kako ga narediti avtomatiziranega z Outlookom VBA. Preberite, če želite izvedeti korake in ustrezne kode.

Samodejni izvoz informacij o dohodni e-pošti v datoteko Excel

1. Najprej bi morali ustvariti datoteko Excel.

• Odprite novo datoteko Excel.
• Nato vnesite »Ne«. v celici A1, »Ime pošiljatelja« v celici B1, »E-poštni naslov pošiljatelja« v celici C1 in »Zadeva e-pošte« v celici D1 ter »Čas prejema« v celici E1, kot je naslednja slika.
• Nazadnje ga shranite v želeno ime in želeno mapo.

2. Po tem bi morali zagnati Outlook.
3. Nato pritisnite tipke "Alt + F11", ki vas bodo pripeljale do urejevalnika VBA.
4. Nato v pojavnem oknu dvakrat kliknite »ThisOutlookSession« na levi strani.
5. Nato morate v oknu projekta »ThisOutlookSession« kopirati in prilepiti naslednje kode VBA.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Kasneje bi morali podpisati to kodo.
7. V nadaljevanju je restart Outlook za aktiviranje novega projekta VBA.
8. Sčasoma bodo od zdaj naprej vsa dohodna e-poštna sporočila samodejno izvožena v prednastavljeno Excelovo datoteko takoj, ko bodo prispela v mapo Prejeto. Excelova datoteka bo videti kot naslednja slika:

Preprečite bolečo poškodbo podatkov PST

Outlook si je zaradi svojih različnih funkcij prislužil veliko pohval. Vendar to ne pomeni, da je varno. Še vedno je lahko kadar koli ogrožena. Če na primer pogosto nepravilno zapirate Outlook, je zelo verjetno, da bodo vaši podatki PST ogroženi. V tem primeru, če bi želeli popravilo PST podatkov, se morate zateči k izkušenemu orodju, kot je npr DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z izterjati mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com