3 hitri načini brisanja praznih vrstic in stolpcev v tabeli Word

V tej objavi vam bomo razložili 3 hitre načine za brisanje praznih vrstic in stolpcev v tabeli Word.

Tabele so bistvene za dokument, zlasti pri hrambi različnih vrst podatkov. Včasih lahko dolga tabela preseže stran in se razteza na več. Ko je miza torej dolga in zapletena, lahko ukrepe poenostavite. Tako lahko na primer izbrišete nepotrebne prazne vrstice in stolpce.

Sledijo 3 metode, ki jih lahko uporabite.

1. način: Ročno izbrišite prazne vrstice in stolpce

1. Najprej izberite prazno vrstico ali stolpec.
2. Nato z desno miškino tipko kliknite kontekstni meni. V meniju izberite »Izbriši vrstice« ali »Izbriši stolpce«.

Na žalost ne morete izbrati več zaporednih vrstic ali stolpcev in jih na ta način izbrisati. Za to povpraševanje se lahko sklicujete na naš prejšnji članek: 5 hitrih metod za paketno brisanje več vrstic ali stolpcev v tabeli Word

2. način: paketno izbrišite vse prazne vrstice in stolpce v tabeli

Metoda 1 ima svoje omejitve. Ponudili vam bomo način paketnega odstranjevanja vrstic in stolpcev v tabeli s pomočjo kod VBA.

1. Za začetek postavite kazalec v ciljno tabelo.
2. Drugič, sprožite urejevalnik VBA s pritiskom na “Alt + F11”.
3. V urejevalniku najprej kliknite projekt »Normal«.
4. Nato v menijski vrstici kliknite jeziček »Vstavi«.
5. V spustnem meniju izberite »Modul«.
6. Dvokliknite modul, da ga odprete in tja prilepite naslednje kode:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Na koncu kliknite gumb »Zaženi« v menijski vrstici ali pritisnite »F5«.

V nekaj sekundah boste v tej tabeli odstranili vse prazne vrstice in stolpce.

3. način: paketno izbrišite vse prazne vrstice in stolpce v vseh tabelah v dokumentu

1. Najprej ponovite korake v 2. metodi, da namestite in zaženete makro.
2. Le tokrat makro zamenjajte z naslednjim:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Obnovi zlomljen dokument

Dandanes obstaja več kot le en način za obnovitev izgubljenih podatkov. Na primer, varnostne kopije ostajajo vedno vaša glavna prioriteta. Če to ne zadovolji vaše potrebe po obnovi najnovejših informacij, lahko poskusite ... popravilo dokumenta orodje.

Uvod avtorja:

Vera Chen je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z xlsx popravilo in pdf popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com