2 načina za hitro spajanje več Wordovih dokumentov v enega prek VBA

V tem članku z veseljem delimo z vami 2 načina za hitro združitev več Wordovih dokumentov v enega prek VBA.

V Wordu je privzeta vgrajena funkcija, ki uporabniku pomaga združiti ali združiti več dokumentov v enega. Podrobnosti so razložene v tem članku: Kako združiti in združiti več Wordovih dokumentov v enega

Pri tej metodi morate narediti nekaj klikov in vsebina naslednjega dokumenta vedno pride takoj za vsebino prejšnjega. Zato vam želimo ponuditi hitrejše načine za to.

1. način: Združite izbrane dokumente v enega

1. Najprej in predvsem ustvarite nov prazen dokument.
2. Zaženite urejevalnik VBA v Wordu s pritiskom na »Alt+ F11«.
3. Nato kliknite »Normal«.
4. Nato kliknite »Vstavi«.
5. In izberite "Modul".
6. Dvokliknite nov modul, da odprete prostor za urejanje.
7. Tam prilepite naslednji makro:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Nato kliknite »Zaženi« ali pritisnite »F5«.
9. Zdaj v oknu »Prebrskaj« izberite več datotek s pritiskom na »Ctrl« in kliknite »V redu«.
10. Nato bo vsa vsebina izbranih datotek združena v novem dokumentu, pri čemer se bodo besedila vsakega dokumenta začela na novi strani.

Opomba:

Kot smo omenili, ta makro postavi besedila vsakega dokumenta na novo stran. Če pa želite, da so ena za drugo, lahko spremenite nekaj kodnih vrstic v makru. Samo poiščite vrstico »If nEachSelectedFile < nTotalFiles Then«, jo izbrišite in tudi naslednjih šest vrstic.

2. način: Združite vse dokumente v mapi v enega

Če imate mapo z datotekami, ki jih želite združiti, bo ta makro deloval čudovito.

1. Za začetek namestite in zaženite makro, kot je opisano v 1. metodi.
2. Nato zamenjajte makro s tem:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Zaženite makro s klikom na "Zaženi".
4. Nato vidite odprto okno »Prebrskaj«. Izberite mapo, kamor želite shraniti vse dokumente. In kliknite »V redu«.

Podobno se besedila vsakega dokumenta začnejo na novi strani. Če želite, da se zlepijo eno za drugim, poiščite in izbrišite vrstico kode ».InsertBreak Type:=wdPageBreak«.

Pravilno zaščitite svoj Wordov dokument

Eden najboljših načinov za zaščito vaših Wordovih dokumentov je, da jih redno varnostno kopirate. Z varnostnimi kopijami v roki se vam nikoli ne bo treba bati izgube podatkov. Poleg tega je priporočljivo, da dobite orodje za popravilo docx če bo katera od njih poškodovana.

Uvod avtorja:

Vera Chen je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z poškodovan Excel in pdf popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com