2 hitra načina iskanja ali brisanja stavkov, ki vsebujejo določeno besedilo v vaši besedi

V tem članku vam bomo ponudili 2 hitra načina za iskanje ali brisanje stavkov, ki vsebujejo določeno besedilo v vašem Wordu.

Vsi vemo, da lahko v Wordu s funkcijo »Najdi in zamenjaj« preprosto poiščemo vse pojavitve določenih besed. Potem ne bomo imeli težav z njihovim označevanjem, zamenjavo ali odstranjevanjem. Kot vidite, je cilj beseda ali besedna zveza. Danes pa vam z veseljem predstavljamo makro način za iskanje ali brisanje stavkov, ki vsebujejo določeno besedilo.

1. način: Poiščite ali izbrišite stavke, ki vsebujejo določeno besedilo

1. Za začetek pritisnite »Alt + F11«, da sprožite urejevalnik VBA v Wordu.
2. Nato ustvarite nov modul s klikom na »Normalno«.
3. Nato kliknite »Vstavi« in izberite »Modul«, da dobite novega.
4. In odprite modul z dvoklikom.
5. Zdaj prilepite naslednje kode:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Nato kliknite »Zaženi«.
7. Pojavilo se bo polje za vnos, v katerega boste morali vnesti besedilo. Samo vnesite skupno besedilo, ki ga vsebujejo vsi stavki. Kliknite »V redu«.
8. Nato boste videli stavek, ki vsebuje izbrano besedilo, s pozivom v sporočilnem oknu. Kliknite »Da«, da izbrišete stavek, in »Ne«, da ga obdržite.
9. Po potrditvi je izbran naslednji stavek z določenim besedilom. Pojavi se tudi potrditveno polje. Makro vas namreč popelje skozi celoten dokument, pri čemer poišče ciljne stavke in vsakič zahteva vašo potrditev.

2. način: Poiščite ali izbrišite stavke, ki vsebujejo poljubno besedilo na seznamu

Z makrom v 1. metodi lahko iščete samo eno besedo ali besedno zvezo naenkrat. Vsekakor lahko večkrat zaženete makro, da poiščete več primerkov besed ali besednih zvez. Da bi izpolnili potrebo po večkratnem iskanju, vam bomo ponudili še en makro.

1. Najprej vsa ciljna besedila postavite v nov dokument. Prepričajte se, da vsak del besedila zaseda en odstavek brez presledka. Zaprite in shranite dokument.
2. Nato namestite in zaženite makro z natančnimi koraki v 1. metodi.
3. Nato zamenjajte makro s tem:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Zdaj se odpre okno »Prebrskaj«. Izberite pravkar shranjen dokument in kliknite »Odpri«.
5. Naslednji postopek je enak kot pri 1. metodi.

Pristop k obravnavanju poškodovanih dokumentov

Izguba dragocenih podatkov je naravnost uničujoča. Lahko celo ogrozi vaše podjetje. Da bi se izognili takšnim frustracijam, morate dobiti a Beseda popraviti orodje čim prej. Tako orodje vam bo pomagalo zmagati v boju s poškodovanimi dokumenti.

Uvod avtorja:

Vera Chen je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z popraviti Excel in pdf popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com