2 hitra načina za izvoz seznama vseh označenih Outlookovih e-poštnih sporočil v Excel

Če želite izvoziti seznam vseh označenih e-poštnih sporočil iz nabiralnika Outlook v Excel, lahko uporabite enega od dveh načinov, ki sta v skupni rabi v tem članku.

Na primer, če želite pravočasno obravnavati vsa označena e-poštna sporočila ali jih deliti z nekom drugim, morda upate, da jih boste izvozili v Excelov delovni list. Tukaj bomo predstavili 2 pristopa za njegovo uresničitev. Prvi uporablja standardno funkcijo »Uvoz in izvoz«, potem ko najde označena e-poštna sporočila. Če sem iskren, je malo dolgočasno. Tako vas bomo v slednjem naučili bolj priročnega načina, ki uporablja VBA.

1. način: ročno izvozite vsa najdena označena e-poštna sporočila

1. Najprej kliknite v iskalno polje nad poštnim seznamom.
2. Nato kliknite »Vsi poštni elementi« v skupini »Obseg« na zavihku »Iskanje«.
3. Nato kliknite gumb »Označeno« v skupini »Določi«.
4. Ko so na seznamu prikazana vsa označena e-poštna sporočila, izberite eno sporočilo in pritisnite »Ctrl + A«, da izberete vse.
5. Nato pritisnite bližnjične tipke »Ctrl + Shift + V«.
6. V novem pogovornem oknu ustvarite novo mapo pod Outlookovo datoteko.
7. Kasneje izberite novo ustvarjeno mapo in kliknite »V redu«, kar bo premaknilo vsa najdena označena e-poštna sporočila v novo mapo.
8. Nato kliknite »Datoteka« > »Odpri« > »Uvozi«,
9. V pojavnem pogovornem oknu izberite »Izvozi v datoteko« > »Naprej« > »Microsoft Excel 97-2003« > »Naprej«.
10. Na novem zaslonu izberite pravo mapo in pritisnite »Naprej«.
11. Nato sledite čarovnikom, da dokončate »Izvoz«.
12. Dobili boste novo Excelovo datoteko, prikazano kot naslednji posnetek zaslona.

2. način: izvozite seznam vseh označenih e-poštnih sporočil prek VBA

1. V Outlooku pritisnite »Alt + F11«, da sprožite urejevalnik VBA.
2. Nato omogočite »MS Excel Object« v skladu z »Kako dodati Lib predmetarary Referenca v VBA".
3. Nato kopirajte spodnjo kodo VBA v modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Na koncu postavite kazalec v podprogram »ExportAllFlaggedEmailsToExcel« in pritisnite tipko »F5«.
5. Nato v novem pogovornem oknu izberite Outlookovo datoteko.
6. Ko prejmete poziv »Dokončano«, boste prejeli tudi novo Excelovo datoteko, kot je spodnja slika.

Zaščitite svoj Outlook pred korupcijo

Outlook je nagnjen k napakam in korupciji, zato je za nas zelo težka naloga, da zaščitimo svoje Outlookove podatke. Nedvomno je most učinkovit in praktičen način je izdelava rednih varnostnih kopij podatkov za Outlook. Poleg tega je nujno, da se dokopamo do zmogljivega in zaupanja vrednega Outlookovega orodja za popravke, kot je npr. DataNumen Outlook Repair. Prišlo bo prav, če orodje za popravilo nabiralnika nima učinka.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z fiksna SQL Server in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com