Ako exportovať štruktúru priečinkov súboru programu Outlook do Excelu

Ak chcete rýchlo exportovať štruktúru priečinkov dátového súboru programu Outlook do zošita programu Excel, môžete použiť metódu uvedenú v tomto článku.

Z určitých dôvodov, ako je napríklad zaznamenávanie aktuálnych priečinkov a podpriečinkov programu Outlook, mnohí používatelia dúfajú, že exportujú štruktúru priečinkov súboru programu Outlook do externého súboru, napríklad zošita programu Excel. V nasledujúcom texte sa s vami podelíme o kúsok kódu VBA, ktorý vám ho môže pomôcť dosiahnuť v okamihu.

Exportujte štruktúru priečinkov súboru programu Outlook do Excelu

1. Najprv spustite aplikáciu Outlook.
2. Potom v hlavnom okne programu Outlook stlačte klávesové skratky „Alt + F11“.
3. Ďalej sa dostanete do editora Outlook VBA, v ktorom by ste mali otvoriť nepoužívaný modul.
4. Následne môžete do tohto modulu skopírovať nasledujúci kód VBA.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Potom by ste sa mali uistiť, že program Outlook povolil makrá.
6. Nakoniec môžete urobiť snímku:

• V aktuálnom okne makra stlačte tlačidlo F5.
• Po dokončení makra dostanete upozornenie s výzvou „Dokončiť“.
• Neskôr môžete prejsť do preddefinovaného lokálneho priečinka a nájsť nový súbor Excel. Otvorte ho a bude to vyzerať ako nasledujúca snímka obrazovky:

Nikdy neignorujte žiadne chyby programu Outlook

Napriek množstvu možností je Outlook rovnako náchylný na chyby a poškodenie ako iní e-mailoví klienti. Preto by ste mali prikladať dôležitosť všetkým chybám v programe Outlook. Neignorujte ich, prosím. V opačnom prípade môže hromadenie chýb nakoniec viesť k poškodeniu programu Outlook. Ak sa stretnete so zauzlenými chybami, odporúča sa použiť výkonný nástroj, ako napr DataNumen Outlook Repair, ktorý môže opraviť Outlook chyby v priebehu niekoľkých sekúnd.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane zotavenie sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S