Ako rýchlo nájsť odseky s jednou vetou v dokumente Word

V tomto príspevku vám chceme ukázať rýchly spôsob, ako nájsť všetky jednovetné odseky vo vašom dokumente programu Word pomocou VBA.

Občas môžu mať niektoré dokumenty veľmi konkrétne požiadavky na ich formátovanie a štruktúru. Napríklad vám nemusí byť dovolené mať odseky iba s jednou vetou. Tieto odseky nie je ťažké rozpoznať, vyžaduje to však čas, najmä je to dlhý dokument.

Dnes vám ponúkneme rýchly spôsob špecifikácie všetkých odsekov s jednou vetou v dokumente.

Vyhľadajte všetky odseky s jednou vetou v jednom dokumente

1. Po prvé, Word počíta bodku ako vetu. Takže ak existujú slová ako „Pán“ alebo „Pani“, Word to považuje za vetu. Ak chcete vylúčiť takéto rozptýlenie, musíte nahradiť slovo „Mr.“ s „pánom“. A keď dokončíte hľadanie odseku s jednou vetou, môžete ich zmeniť späť. Ak chcete nahradiť slová, môžete odkazovať na tento odkaz: Ako nájsť a nahradiť viac položiek v dokumente Word
2. Potom stlačte kombináciu klávesov „Alt + F11“ a spustite editor VBA.
3. Potom kliknite na „Normálny“ projekt.
4. Kliknite na kartu „Vložiť“ na paneli s ponukami a v rozbaľovacej ponuke zvoľte „Modul“.
5. Ďalej dvojitým kliknutím otvorte modul.
6. Vložte nasledujúce kódy do modulu:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. V neposlednom rade kliknite na tlačidlo „Spustiť“ alebo stlačte „F5“.

Dostanete takúto správu s informáciou, že práca je hotová.

Nájdite všetky odseky s jednou vetou vo viacerých dokumentoch

1. Na začiatok musíte všetky cieľové dokumenty umiestniť do priečinka.
2. Potom nainštalujte a spustite nasledujúce makro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. V otvorenom okne „Prehliadať“ vyberte priečinok, kde máte uložené dokumenty, a kliknite na tlačidlo „OK“.

Makro potom zvýrazní všetky odseky s jednou vetou a nechá dokumenty otvorené. Ak dokument neobsahuje odsek s jednou vetou, uzavrie sa. Okrem toho je k dispozícii schránka so správou označujúca počet odsekov s jednou vetou v každom dokumente.

Riešiť prípad straty údajov

Chyby používateľa a náhly výpadok napájania môžu mať za následok smrť Wordu. Aj keď zbalený Word môže nielen ovplyvniť každodennú prácu, ale aj viesť k poškodenie dokToto v žiadnom prípade nie je najnepríjemnejšia časť dátovej katastrofy. Je lepšie okamžite si zaobstarať opravný nástroj na obnovenie dát.

Úvod autora:

Vera Chen je expertka na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane zotaviť excelovať a pdf oprava softvérových produktov. Pre viac informácií navštívte www.datanumen. S