Ako rýchlo exportovať celkový čas strávený na schôdzkach programu Outlook v každej farebnej kategórii

Ak chcete vytvoriť správu o celkovom čase, ktorý venujete schôdzkam v každej farebnej kategórii, môžete použiť metódu uvedenú v tomto článku. Môže vám to pomôcť dosiahnuť v krátkom čase bez toho, aby ste museli počítať ručne.

Mnoho používateľov je zvyknutých zaznamenávať väčšinu svojich aktivít v kalendári programu Outlook. Aby ich bolo možné ľahšie spravovať a rozlišovať, priraďujú ku každej z nich kategórie. V takom prípade by niektorí používatelia chceli vygenerovať správu zobrazujúcu celkový čas strávený na položkách kalendára v každej farebnej kategórii. Niet pochýb o tom, že manuálne počítanie a zadávanie je zložité. Preto sa tu podelíme o spôsob, ako túto úlohu vykonať jednoduchým kliknutím.

Exportujte celkový čas strávený na schôdzkach v každej farebnej kategórii

1. Na prvom mieste spustite aplikáciu Outlook.
2. Po vstupe do okna Outlooku potom môžete klepnúť na klávesové skratky „Alt + F11“.
3. Následne získate prístup do okna „Microsoft Visual Basic for Applications“.
4. Ďalej budete musieť povoliť „Knižnicu objektov programu Microsoft Excel“. Kliknite na „Nástroje“ > „Referencie“.
5. Potom by ste mali nájsť a otvoriť modul, ktorý sa nepoužíva.
6. Potom musíte do tohto modulu skopírovať nasledujúci kód VBA.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Nakoniec môžete toto makro spustiť, a to bez ohľadu na kliknutie na ikonu „Spustiť“ na paneli nástrojov alebo stlačenie klávesu „F5“.
8. Potom sa zobrazí výzva na výber konkrétneho kalendára.
9. Po výbere a stlačení tlačidla „OK“ sa makro bude naďalej spúšťať. Po dokončení bude na pozadí nový súbor Excel.
10. Máte k nej prístup. Bude to vyzerať ako na nasledujúcej snímke obrazovky:

Dávajte pozor na potenciálne hrozby týkajúce sa vášho Outlooku

Používatelia Outlooku by si mali dávať pozor na všetky potenciálne riziká vrátane neznámych príloh e-mailov, vložených odkazov a ľudských chýb. V opačnom prípade sa váš program Outlook môže kedykoľvek poškodiť. Nevyhnutnosťou je tiež pravidelné zálohovanie údajov programu Outlook a údržba špecializovaného nástroja na opravu. DataNumen Outlook Repair je jeden z najviac odporúčaných nástrojov na opravu. Dokáže opraviť Outlook problémy za okamih.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane poškodený mdf a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S