Ako rýchlo exportovať všetky hypertextové odkazy do viacerých e-mailov programu Outlook do programu Excel

Keď potrebujete extrahovať všetky hypertextové odkazy z jedného alebo viacerých e-mailov, je hlúpe kopírovať ich jeden po druhom. Tento príspevok vás naučí metódu, ako rýchlo exportovať všetky hypertextové odkazy z mnohých e-mailov do Excelu.

Z niektorých dôvodov, napríklad prihlásenie hypertextových odkazov do všetkých vašich odoslaných e-mailov, budete musieť hypertextové odkazy extrahovať. Bez akýchkoľvek pochybností sa neodporúča manuálne ich extrahovať a kopírovať. Musíte túžiť po oveľa inteligentnejšom prístupe, ako je napríklad použitie VBA. Tu vám poskytneme taký kúsok kódu VBA, ktorý dokáže jednoduchým kliknutím exportovať všetky hypertextové odkazy v mnohých e-mailoch do programu Excel.

Exportujte všetky hypertextové odkazy vo viacerých e-mailoch do programu Excel

1. Najprv spustite program Outlook ako obvykle.
2. Potom musíte v okne Outlooku stlačiť klávesové skratky „Alt + F11“.
3. Okamžite získate prístup k editoru Outlook VBA.
4. Následne musíte povoliť „Knižnicu objektov programu Microsoft Word“ a „Knižnicu objektov programu Microsoft Excel“. Kliknite na „Nástroje“ > „Odkazy“ a potom ich povoľte v kontextovom dialógovom okne.
5. Ďalej musíte otvoriť nepoužívaný modul, do ktorého musíte do tohto modulu skopírovať kód VBA uvedený nižšie.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Potom môžete opustiť aktuálne okno editora VBA.
7. Neskôr otvorte „Možnosti programu Outlook“ a prispôsobte Panel s nástrojmi Rýchly prístup tak, aby ste pridali novo pridané makro na Panel s nástrojmi Rýchly prístup.
8. Nakoniec môžete urobiť záber:

• Najskôr v zozname e-mailov vyberte e-maily, ktorých hypertextové odkazy chcete extrahovať.
• Potom kliknite na tlačidlo makra na paneli s nástrojmi Rýchly prístup.
• Po dokončení makra získate súbor Excel, napríklad obrázok nižšie:

Opravte neočakávané problémy s programom Outlook

Problémy s Outlookom sa môžu z času na čas vyskytnúť bez akýchkoľvek predstáv. Pokiaľ však ide o malé chyby, Outlook sa dá opraviť jednoduchým reštartom alebo jeho... nástroj na opravu doručenej pošty. Ale ak narazíte na vážne problémy, vnútorné prostriedky nebudú mať účinok. V tomto okamihu je vaša posledná možnosť určite renomovanejším a robustnejším nástrojom, ako napr DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane poškodený mdf a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S