Ako rýchlo exportovať podrobnosti všetkých členov kontaktnej skupiny programu Outlook do programu Excel

V predvolenom nastavení vidíte iba mená členov a e-mailové adresy v skupine kontaktov. Ak chcete získať ďalšie podrobnosti členov, môžete použiť spôsob uvedený v tomto článku.

Po dvojitom kliknutí na otvorenie skupiny kontaktov v jej okne uvidíte iba mená a e-mailové adresy členov skupiny. Nemôžete získať ďalšie podrobnosti členov, ako napríklad spoločnosť, pracovnú pozíciu, telefónne číslo alebo adresu firmy atď. Všeobecne platí, že ak chcete získať tieto podrobnosti, musíte nájsť kontakty zodpovedajúce členom vo vašom priečinku Kontakty ručne. Je to príliš nepríjemné. Tu vám ukážeme kúsok kódu VBA, ktorý dokáže tieto podrobnosti rýchlo exportovať do zošita programu Excel.

Exportujte podrobnosti všetkých členov v kontaktnej skupine do programu Excel

1. Najprv spustite aplikáciu Outlook.
2. Potom by ste mali stlačiť klávesové skratky „Alt + F11“ v hlavnom okne programu Outlook.
3. Ďalej v novom okne „Microsoft Visual Basic for Applications“ musíte otvoriť nepoužívaný modul alebo priamo vložiť nový modul.
4. Následne skopírujte a prilepte nasledujúci kód VBA do tohto modulu.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Potom môžete pre pohodlnú kontrolu pridať nový projekt VBA na panel nástrojov alebo pásku s nástrojmi Rýchly prístup.
6. Neskôr nastavte úroveň zabezpečenia makra programu Outlook na nízku.
7. Nakoniec to môžete vyskúšať.

• Najskôr vyberte skupinu kontaktov.
• Potom stlačte tlačidlo makra na paneli s nástrojmi alebo na páse s nástrojmi Rýchly prístup.
• Makro sa okamžite spustí.
• Po dokončení dostanete výzvu „Dokončené!“
• Potom môžete prejsť do preddefinovaného cieľového miestneho priečinka, v ktorom nájdete nový súbor programu Excel.
• Otvorte ho a uvidíte kontaktné údaje členov skupiny, ako je nasledujúca snímka obrazovky:

Nerobte paniku tvárou v tvár problémom s programom Outlook

Nikto nie je ochotný akceptovať žiadne problémy s programom Outlook, bez ohľadu na to, či sa zobrazí chybové hlásenie alebo poškodený Outlook dátový súbor. Preto budú mať používatelia pri problémoch s Outlookom sklon k panike. Ak chcete v takom prípade zachovať pokoj, mali by ste mať po ruke dve nevyhnutnosti. Jedným z nich je aktuálne zálohovanie údajov programu Outlook. Tou druhou je napríklad silný softvér na opravu programu Outlook DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane zotavenie sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S